* zlib_example
*
* Example of using the Zlib classes of FoxCrypto with
* a continuous status update.  This technique can be
* used with some sort of progress bar control.
*
* Zlib compression is guaranteed to return a string
* that is of equal or lesser length than the original.
* This makes Zlib compression a good candidate for
* compressing Memo field data.  Decompression follows
* analogous steps.

* This is the way to do this in one function call:
* SET LIBRARY TO FoxCrypto
* lcCompressed = ZlibCompressor( tcBinary, tnDeflateLevel )

#DEFINE BLOCK_SIZE	1024

DECLARE Sleep IN win32api AS Sleep INTEGER tnMilliseconds

SET LIBRARY TO FoxCrypto

LOCAL lnHandle, lcInString, lcOutString

lcInString = REPLICATE("Test String...", 10000)

LOCAL lnInStringLength, lnOutStringLength, lnProcessSize

lnInStringLength = LEN(lcInString)
lnProcessSize = 0

LOCAL i, lnHandle, lnSize

* create a ZlibCompressor object and store its handle
* 9 is the highest possible compression level, and the slowest
lnHandle = ZlibCompressorCreate(9)

IF lnHandle > 0
  FOR i = 1 TO lnInStringLength STEP BLOCK_SIZE
    * add a block of data to the compressor
    lnProcessSize = lnProcessSize + ;
      ZlibCompressorPut(lnHandle, SUBSTR(lcInString, i, BLOCK_SIZE))
    * give a status update
    SET MESSAGE TO "ZlibCompressor " + ;
      TRANSFORM(lnProcessSize) + ;
      " of " + ;
      TRANSFORM(lnInStringLength) + ;
      ", " + ;
      TRANSFORM(lnProcessSize / lnInStringLength * 100, "999.99") + "%"
    Sleep(200) && slow it down so we can see the messages
  ENDFOR
  * the compressor must be closed before the compressed string
  * is read back
  IF !ZlibCompressorClose(lnHandle)
    DO ReportError WITH ;
      "ZlibCompressor object close failed.", lnHandle
  ELSE
    * we will read back the whole string at once, we could
    * read it back in blocks
    lnSize = ZlibCompressorMaxRetrievable(lnHandle)
    IF lnSize < 1
      DO ReportError WITH ;
        "ZlibCompressor object has no compressed data to read.", lnHandle
    ELSE
      lcOutString = ZlibCompressorGet(lnHandle, lnSize)
      * destroy the compressor object
      IF !ZlibCompressorDestroy(lnHandle)
        DO ReportError WITH ;
          "ZlibCompressor object destruction failed."
      ELSE
        * give the final status
        SET MESSAGE TO "ZlibCompressor " + ;
          TRANSFORM(lnInStringLength) + ;
          " of " + ;
          TRANSFORM(LEN(lcOutString)) + ;
          ", " + ;
          TRANSFORM(LEN(lcOutString) / lnInStringLength * 100, ;
          "999.99") + "%"
      ENDIF
    ENDIF
  ENDIF
ELSE
  DO ReportError WITH ;
    "ZlibCompressor object creation failed."
ENDIF

PROCEDURE ReportError ( tcMessage, tnHandle )
  SET MESSAGE TO
  IF PCOUNT() > 1
    * try to clean up
    ZlibCompressorDestroy(tnHandle)
  ENDIF
  ERROR(tcMessage)
ENDPROC