If the methods call properties or methods of the form, then Hilmar's recommendation is best. It is just better practice anyway. If the methods are generic and don't reference specific form properties or methods, then move them to a common program of shared functions or open the form minimized and call the method.

llcontinue = .T.
myvalue = "START VALUE"
oform1 = NEWOBJECT('form1')
oform2 = NEWOBJECT('form2')
oform1.show(0)
oform2.show(1)
DO WHILE llcontinue
	READ EVENTS
ENDDO
IF TYPE('oform1')="O" .and. !ISNULL(oform1)
	oform1.release()
ENDIF
IF TYPE('oform2')="O" .and. !ISNULL(oform2)
	oform2.release()
ENDIF
oform1 = null
oform2 = null
RELEASE oform1, oform2
RETURN

DEFINE CLASS form1 AS form


	DoCreate = .T.
	Caption = "Form1"
	Name = "FORM1"


	ADD OBJECT text1 AS textbox WITH ;
		ControlSource = "myvalue", ;
		Height = 23, ;
		Left = 60, ;
		Top = 48, ;
		Width = 100, ;
		Name = "Text1"


	ADD OBJECT command1 AS commandbutton WITH ;
		Top = 132, ;
		Left = 120, ;
		Height = 27, ;
		Width = 84, ;
		Caption = "Enter Text", ;
		Name = "Command1"

	PROCEDURE DESTROY
	   llcontinue = .F.
		IF TYPE('oform2')="O" .and. !ISNULL(oform2)
			oform2.release()
		ENDIF
	   DODEFAULT()
	ENDPROC

	PROCEDURE setvalue
		myvalue = "NEW VALUE"
	ENDPROC


	PROCEDURE command1.Click
		thisform.setvalue()
		thisform.refresh()
	ENDPROC


ENDDEFINE

DEFINE CLASS form2 AS form


	DoCreate = .T.
	Caption = "Form2"
	Name = "FORM2"


	ADD OBJECT text1 AS textbox WITH ;
		ControlSource = "myvalue", ;
		Height = 23, ;
		Left = 60, ;
		Top = 48, ;
		Width = 100, ;
		Name = "Text1"


	ADD OBJECT command1 AS commandbutton WITH ;
		Top = 132, ;
		Left = 120, ;
		Height = 27, ;
		Width = 132, ;
		Caption = "Call Form1 Method", ;
		Name = "Command1"


	PROCEDURE DESTROY
	   llcontinue = .F.
		IF TYPE('oform1')="O" .and. !ISNULL(oform1)
			oform1.release()
		ENDIF
	   DODEFAULT()
	ENDPROC

	PROCEDURE command1.Click
		IF TYPE('oform1')="O" .and. !ISNULL(oform1)
			oform1.setvalue()
			thisform.refresh()
		ENDIF
	ENDPROC


ENDDEFINE

>I have a number of methods on a form. Is there anyway I can use these methods on my new form?