>Hi,
>
>I want to convert a Excel file to a DBF file, how to coding ?
>Just convert it, no need to open and read the excel file contents.
>
>Regards,
>Derek Yim

Derek,
Converting it to a dbf might not be as simple as it sounds under all cases. For regular stuff there are many ways to do it. Two of these below:

#Define xlDBF3 8
lcXLSFile = Sys(5)+Curdir()+"MyXLS.xls"
lcOutPath = 'XLSheets'
If !Directory(m.lcOutPath)
	Md (m.lcOutPath)
endif
ox = Createobject('Excel.Application')
With ox
  .Workbooks.Open(m.lcXLSFile)
  For Each loSheet In .ActiveWorkbook.Sheets
  	If loSheet.UsedRange.Rows.Count > 0
  		loSheet.Activate
  		loSheet.Range('A1').Select
	    loSheet.SaveAs(Addbs(Fullpath(m.lcOutPath))+loSheet.Name, xlDBF3)
    endif
  Endfor
  .ActiveWorkbook.Saved = .T.
  .Quit
Endwith

lcXLS = Sys(5)+Curdir()+'myXLS.xls'
lcConn = "Driver={Microsoft Excel Driver (*.xls)};"+;
  "DriverId=790;Dbq="+m.lcXLS+;
  ";DefaultDir="+JustPath(m.lcXLS)+";" 
lnHandle = SQLStringConnect(m.lcConn) 
SQLTables(m.lnHandle,"", "SheetNames")

Scan
	lcTableName = Trim(SheetNames.Table_Name)
	lcOutput = Chrtran(m.lcTableName,' $','_')
	SQLExec(m.lnHandle,'select * from ['+m.lcTableName+']',m.lcOutput )
endscan
SQLDisconnect(m.lnHandle)
* Select and browse cursors in data session

Cetin