Tim, try this:

use your_table
Genfieldname="lcfile"	&& General field name

GO (recno_you_need)

local oForm
oForm = Createobject('_Form',GenFieldName)
WITH oForm.myOle1
	IF .oleclass="Excel.Sheet"
		ERASE c:\hi.xls
		.object.saveas("c:\hi.xls")  && it creates the file, 
                            *  but with the Hidden Window
		
		* now open the file, unhide Window and save again
		oExcel=CREATEOBJECT("Excel.Application")
		WITH oExcel
			.DisplayAlerts = .f.
			.Workbooks.Open("c:\hi.xls")
			.Windows(1).visible=.t.
			.Workbooks(1).Save()
		ENDWITH

		oExcel.Quit
		oExcel=.null.
		RELEASE oExcel

	ELSE
		?"?  OLeclass: ", .oleclass
	endif	
ENDWITH

=oForm.Release()

RETURN
*----------------
Define Class _Form As Form
	PROCEDURE iNIT
		LPARAMETERS pGenFieldName
		this.addobject('myOLe1',"OleBoundControl")
		this.myole1.ControlSource = ALIAS()+'.'+pGenfieldName
	ENDPROC
Enddefine
*-------------------------------------

>Hi,
>I have an Excel Document stored in a General Field. (I know they are hard to get out thats why I want to move away from them..). Anyways I have some old data I need to extract from teh General Fields and save as a file.
>
>I tried all posted code about this but nothing works:
>
>Does anyone have a way to get specifically excel files out of the general field and save it as a file?
>
>Tim