Hi Malcolm.

No luck here as well. I'm going to try Chad Bourque's suggestion of using the Windows version of LockScreen and see if that makes a difference.

Here is some code you can use - put it in a form method called ReallyLockScreen and call it like this:

Thisform.ReallyLockScreen( .T. )

***********************************************************************
* Program....: REALLYLOCKSCREEN
* Purpose....: Use the Windows API to force a true screen lock. 
* ...........: Calling this lock function with a handle of 0 unlocks all locked windows
***********************************************************************
LPARAMETERS tlLock
LOCAL ARRAY laJunk[1]
LOCAL lnHWnd, lnRes
**********************************************************
*** Check that the library has been set up and open it if not already done.
**********************************************************
lnRes = ADLLS( laJunk )
IF lnRes = 0 OR  NOT ( ASCAN( laJunk, 'LockWindowUpdate', 1, -1, 1, 15 ) > 0)
  *** We don't have the function available
  DECLARE INTEGER LockWindowUpdate IN Win32API INTEGER nHandle 
ENDIF
*** Now set the Handle to lock according to the parameter
lnHWnd = IIF( tlLock, ThisForm.HWnd, 0 )
*** And call the function
LockWindowUpdate( lnHWnd )

RETURN