>Is there a way that I can get the columns and structure from MySQL in VFP?
>Can It be done in using ADO?

Check Message #1021710 for ODBC.
You can also get it with ADO if you've OLEDB driver. ie:

#Define adSchemaCatalogs 1
#Define adSchemaColumns 4
#Define adSchemaTables 20

Local oConn As 'ADODB.Connection'
oConn = Createobject('ADODB.Connection')
oConn.Open( "Provider=sqloledb;Data Source=cetin;"+;
  "Initial Catalog=Pubs;Integrated Security=SSPI" )
rstSchema = oConn.OpenSchema(adSchemaColumns)
ShowMe(rstSchema)
rstSchema.Close
oConn.Close

Function ShowMe
  Lparameters toRecordset
  oForm = Createobject('myForm', toRecordset)
  oForm.Show
  Read Events
Endfunc

Define Class myform As Form
  Height = 450
  Width = 750
  Name = "Form1"

  Add Object hflex As OleControl With ;
    Top = 10, Left = 10, Height = 430, Width = 730, Name = "Hflex", ;
    OleClass = 'MSHierarchicalFlexGridLib.MSHFlexGrid'

  Procedure Init
    Lparameters toRecordset
    This.Caption = "Recordset"
    This.hflex.Datasource = toRecordset
    This.hflex.AllowUSerResizing = 3
  Endproc
  Procedure QueryUnload
    Clear Events
  Endproc
Enddefine

Cetin