This always works for me:

LOCAL oPreviewForm
oPreviewForm = createOBJECT('PreviewForm')

REPORT FORM test TO PRINTER PROMPT WINDOW PREVIEWFORM PREVIEW

oPreviewForm.Release

RETURN

*--------------------------------------------------------------------------
DEFINE CLASS previewform AS form


	Height = 250
	Width = 375
	Desktop = .F.
	ShowWindow = 2
	ScrollBars = 3
	DoCreate = .T.
	AutoCenter = .T.
	BorderStyle = 3
	Caption = "Print Preview Window"
	ControlBox = .F.
	Closable = .F.
	MinButton = .F.
	Movable = .F.
	WindowType = 0
	WindowState = 2
	AlwaysOnTop = .F.
	onkeyctrlf10 = "''"
	Name = "previewform"


	PROCEDURE QueryUnload
		lcoldctrlf10setting = THISFORM.onkeyctrlf10
		IF !EMPTY(lcoldctrlf10setting)
			ON KEY LABEL CTRL+F10 &lcoldctrlf10setting
		ENDIF
	ENDPROC


	PROCEDURE Init
		DODEFAULT()
		THISFORM.onkeyctrlf10 = ON('KEY LABEL','CTRL+F10')
		ON KEY LABEL CTRL+F10
		THIS.SHOW()
		CLEAR TYPEAHEAD
	ENDPROC


	PROCEDURE Deactivate
		DODEFAULT()
		IF WEXIST('Report Designer')
			MOUSE DBLCLICK AT -0.1,0.1 WINDOW "Report Designer"
		ENDIF
		IF WEXIST('Print Preview')
			MOUSE DBLCLICK AT -0.1,0.1 WINDOW "Print Preview"
		ENDIF
		keyboard "{ctrl+f10}"
	ENDPROC


ENDDEFINE

>I'm trying to OPEN all Reports (in a project) FULL SCREEN so the User does not have to MANUALLY change to FULL SCREEN for viewing.
>
>Anyone know why the COMMAND "KEYBOARD '{CTRL+F10}'" placed before issuing
>the COMMAND "REPORT FORM formname PREVIEW IN SCREEN" does not work all the time (ie, does not open the report FULL SCREEN)?
>
>Harry