>Hi
>
> I have a Remote Connection for other VFP Databese. I have some Remote Views.
>Now, I want to run a Stored Procedure on that database.
>Stored Procedures is not on Local Database.
>How I can do it?
>
>********************
>In VFP help:
>
>OLE DB Provider for Visual FoxPro
>Calling a stored procedure using the conventional syntax:
>myStoredProc( Param1, Param2, ... )
>********************
>
>But it is for Local Database!!!!!!

No, you can call stored procedures this way from any DBC you access with VFP OLE DB Provider. Here's an example of calling VFP stored procedure that returns a cursor

lcConStr = "Provider=vfpoledb;Data Source=" + lcDBcName
oCon = CreateObject("ADODB.connection")
oCmd = CreateObject("ADODB.Command")
oRs  = CreateObject("ADODB.RecordSet")

oCon.Open(lcConStr)
oCmd.ActiveConnection = oCon
oRs.ActiveConnection = oCon

oCmd.CommandType = 4  && Stored Procedure
oCmd.CommandText = [RetProdRs("C%")]

oRs.Source = oCmd
oRs.Open()
...
* Stored procedure RetProdRs
PROCEDURE RetProdRs
LPARAMETERS tcPar1
SELECT * ;
	FROM prod ;
	WHERE eng_name LIKE tcPar1 ;
	INTO CURSOR crsRetRs 

	EXECSCRIPT([SETRESULTSET("crsRetRs")])
RETURN

This one shows how to call stored procedure that returns scalar value

oCmd.CommandType = 4  && Stored Procedure
oCmd.CommandText = [Test("Date :")]
oRs = oCmd.Execute()
* Display return value
? oRs.Fields("return_value").Value
...
PROCEDURE test(tcPrefix)
RETURN tcPrefix + Dtos(DATETIME())