I guess, you have this.refresh() in the page.activate(). If so, you can just wrap it into thisform.ReallyLockScreen(.t.) and (.f.) methods.

Here is ReallyLockScreen method:

*---------------------- Location Section ------------------------
*   Library: 	Aforms.vcx
*   Class: 		Dataentryform
*   Method: 	Reallylockscreen()
*----------------------- Usage Section --------------------------
*)  Description: Use the Windows API to force a true screen lock.
* ...........: Calling this lock function with a handle of 0 unlocks all locked windows
*)
*   Scope:      Public
*   Parameters:
*$  Usage:
*$
*   Returns:
*--------------------- Maintenance Section ----------------------
*   Change Log:
*       CREATED 	06/03/2005 - Marcia Akins
*		MODIFIED
*----------------------------------------------------------------
lparameters tlLock
local array laJunk[1]
local lnHWnd, lnRes
**********************************************************
*** Check that the library has been set up and open it if not already done.
**********************************************************
lnRes = adlls( laJunk )
if m.lnRes = 0 or  not ( ascan( laJunk, 'LockWindowUpdate', 1, -1, 1, 15 ) > 0)
*** We don't have the function available
	declare integer LockWindowUpdate in Win32API integer nHandle
endif
*** Now set the Handle to lock according to the parameter
lnHWnd = iif( m.tlLock, thisform.hwnd, 0 )
*** And call the function
LockWindowUpdate( m.lnHWnd )
return

>I have a form with a pageframe. One one of the pages are about 200 verticle lines which are used to represent a bar graph. The height of the line is adjusted based on code in the line's refresh event. SInce it takes a moment to perform these calcs, I wanted to turn off the screen at the beginning of the refresh for the first line and turn it back on after the last line has been refreshed. To simplify things I wanted to adjust the order at which the lines are refreshed (height adjusted).
>
>Fabio has given me a solution without answering my question which is fine. Thanks Fabio.
>
>However, there is still a sequential refresh the first time I select the page that has the graph on it. That is, I get to watch the lines adjust themselves one at a time. Why this is happening I don't know.
>
>
>>>Does anyone know if it's possible to control the order in which shapes on a form are refreshed?
>>>
>>>My problem here is that I want to set lockscreen = .t. before the first shape is adjusted and set it to false after the last shape is adjusted. Each shape has its own refresh code independant of the others.
>>>
>>>Thanks in advance for any help.
>>>
>>>- Don
>>
>>What exactly are you doing? Where do you want to set lockscreen? In which method?
>>
>>I think (not sure), that the objects are refreshed based on the order they were added to the form either in design-time or run-time.