>yes but i try use that but i can't, please if yo can give a example.

LPARAMETERS pcWMAoperation

*-----------------------------------------------------------------------------------*
* Victor - 01/24/2002 *
* *
* Requirements: *
* DirectX v6 must be installed on workstation for the encoder engine to operate. *
* *
* Windows Media Component Setup Application needs to be run on workstation to *
* install the Windows Media Encoder Engine. (using 7.01.00.3055) *
* *
* The default session profile file (C:\OrderEnt\WMAsession.wme) must exist. *
* *
*-----------------------------------------------------------------------------------*
* *
* These are the possible parameters here and what they do: *
* *
* LoadEngine = Loads the Windows Media Encoder Engine *
* LoadProfile = Loads the default session profile (.wme file) *
* PushSession = Saves tag info for .wma file. (actually writes new .wme) *
* StartRecording = Starts the recording/encoding process *
* StopRecording = Stops the recording/encoding process *
* ReleaseEngine = Release the Windows Media Encoder Engine *
*-----------------------------------------------------------------------------------*

DO CASE
CASE pcWMAoperation = 'LoadEngine'
IF VARTYPE(owme) <> 'O'
PUBLIC owme
owme = CREATEOBJECT('WMEncEng.WMEncoder')
ENDIF
THISFORM.imgLoad.VISIBLE = THISFORM.vvshowpics

CASE pcWMAoperation = 'LoadProfile'
IF NOT FILE('c:\orderent\WMASession.wme')
COPY FILE S:\UPDATE\wmasession.wme TO C:\OrderEnt
ENDIF

owme.LOAD('C:\OrderEnt\WMAsession.wme')
THISFORM.imgProfile.VISIBLE = THISFORM.vvshowpics

CASE pcWMAoperation = 'PushSession'
WITH owme
.FILE.localfilename = '_' + NextNumber('NxtWaveFile', 7 ) + '.WMA'
.DisplayInfo.Author = ALLTRIM(THISFORM.cRepName)
.DisplayInfo.DESCRIPTION = 'OE Call ' + TTOC(DATETIME()) + ' - ' + ALLTRIM(THISFORM.cRepName) + ' - Approval #: ' + ALLTRIM(THISFORM.txtApprovalNo.VALUE)
.DisplayInfo.TITLE = 'Approval #: ' + ALLTRIM(THISFORM.txtApprovalNo.VALUE)
.DisplayInfo.Copyright = TTOC(DATETIME())
.DisplayInfo.Rating = 'PG' && If no one cusses
.AutoIndex = .T.
.SAVE('C:\OrderEnt\WMAsession.wme')
ENDWITH
THISFORM.wavefile = owme.FILE.localfilename

*---vvvvvvvvvvvvvvvvvvvvvvvvvvvvvv---------*
*= MessageBox('ThisForm.WaveFile being set to: ' + ThisFOrm.WaveFile)
*------------------------------------------*

THISFORM.imgPush.VISIBLE = THISFORM.vvshowpics

CASE pcWMAoperation = 'StartRecording'
owme.START()
THISFORM.imgStart.VISIBLE = THISFORM.vvshowpics

CASE pcWMAoperation = 'StopRecording'
* WAIT WINDOW "Stop recording (2a)..." NOWAIT NOCLEAR
owme.Stop()
* WAIT WINDOW "Stop recording (2b)..." NOWAIT NOCLEAR
WITH THISFORM
.imgLoad.VISIBLE = .F.
.imgStart.VISIBLE = .F.
.imgProfile.VISIBLE = .F.
.imgPush.VISIBLE = .F.
ENDWITH

CASE pcWMAoperation = 'ReleaseEngine'
* WAIT WINDOW "Stop recording (2c)..." NOWAIT NOCLEAR
RELEASE owme

OTHERWISE
= MESSAGEBOX('vvWMAoperations failure! Please contact your system administrator immediately.')
ENDCASE