Brandon,

I don't have that particular file, but I'm assuming that it is just a general purpose marquee scrolling left-right or up-and-down. Throwing one together doesn't take much time... here's one that scrolls up-and-down... cut-n-paste the code below into a prg file and execute it. The code in the timer does most of the work.

PUBLIC oform1

oform1=NEWOBJECT("form1")
oform1.Show
RETURN

DEFINE CLASS form1 AS form

	Height = 207
	Width = 258
	DoCreate = .T.
	Caption = "About"
	Name = "Form1"
	AutoCenter = .T.

	ADD OBJECT container1 AS container WITH ;
		Top = 0, ;
		Left = 9, ;
		Width = 253, ;
		Height = 206, ;
		BorderWidth = 0, ;
		Name = "Container1"


	ADD OBJECT timer1 AS timer WITH ;
		Top = 120, ;
		Left = 36, ;
		Height = 23, ;
		Width = 23, ;
		Interval = 50, ;
		Name = "Timer1"


	PROCEDURE Init
		WITH this.container1
			.ADDOBJECT("edit1", "Editboxscroll")
			WITH .edit1
				.BorderStyle = 0
				.Height = 628
				.Left = 2
				.ReadOnly = .T.
				.ScrollBars = 0
				.Top = 3
				.Width = 249
				.Visible = .T.
			ENDWITH
		ENDWITH
	
		thisform.container1.edit1.top = thisform.container1.Height

		thisform.container1.edit1.value = "MY GREAT SOFTWARE" + CHR(13) + CHR(10) +;
		CHR(13) + CHR(10) +;
		"Copyright © 2005 - All Rights Reserved" + CHR(13) + CHR(10) +;
		CHR(13) + CHR(10) +;
		CHR(13) + CHR(10) +;
		"THE TEAM:" + CHR(13) + CHR(10) +;
		CHR(13) + CHR(10) +;
		"Bill M." + CHR(13) + CHR(10) +;
		CHR(13) + CHR(10) +;
		"Craig S." + CHR(13) + CHR(10) +;
		CHR(13) + CHR(10) +;
		"Doug P." + CHR(13) + CHR(10) +;
		CHR(13) + CHR(10) +;
		"Sue W." + CHR(13) + CHR(10) +;
		CHR(13) + CHR(10) +;
		"and most importantly..." +;
		CHR(13) + CHR(10) +;
		CHR(13) + CHR(10) +;
		"YOU!" + CHR(13) + CHR(10) +;
		"None of this would be possible without you."  + CHR(13) + CHR(10) +;
		CHR(13) + CHR(10) +;
		"THANK YOU"
	ENDPROC

	PROCEDURE timer1.Timer
		WITH thisform.container1.edit1
			IF .Top < (-1 * .Height)
				.Top = thisform.container1.height
			ELSE
				.Top = .Top - 1
			ENDIF
		ENDWITH
	ENDPROC


ENDDEFINE
DEFINE CLASS editboxscroll as EditBox
	PROCEDURE when
		RETURN .F.
	ENDPROC
ENDDEFINE

>Does anyone have the Scrolling Credits Marquee File #9976 ? The link in the downloads section is bad and this would really save me some time not reinventing the weel. Of course if anyone has created a better scrolling marquee type control point me to that too.
>
>
>Thanks.