>The code below is self explanitory, but it isn't working. I have also tried it without the dmy.
>

>.ToolTipText = "Estimated next event date " + TRANSFORM(DMY(thenextdate))
>

>I have tried several ways to accomplish this. Is it possible to do this with a tooltip? If it is, then how do I code it?

This is a TextBox that support dynamic Tooltips:

oForm = CREATEOBJECT("Form1")
oForm.Show()
READ EVENTS


DEFINE CLASS form1 AS form


    Top = 0
    Left = 0
    Height = 40
    Width = 206
    ScrollBars = 1
    DoCreate = .T.
    ShowTips = .T.
    Caption = "Form1"
    nextdate = (DATE())
    Name = "Form1"


    ADD OBJECT command1 AS commandbutton WITH ;
        Top = 9, ;
        Left = 115, ;
        Height = 27, ;
        Width = 84, ;
        Caption = "Change It", ;
        Name = "Command1"


    ADD OBJECT text1 AS TEXTdynamic WITH ;
        Height = 23, ;
        Left = 7, ;
        Top = 10, ;
        Width = 100, ;
        ToolTipText = [="Estimated next event date " + TRANSFORM(DMY(thisform.nextdate))]
        Name = "Text1"


    PROCEDURE command1.Click
        thisform.nextdate = thisform.nextdate + 1
    ENDPROC

    PROCEDURE QueryUnload
        CLEAR EVENTS
    ENDPROC

ENDDEFINE

DEFINE CLASS TEXTdynamic AS TextBox

	PROCEDURE ToolTipText_Access
		
		RETURN IIF(LIKE('=*',m.This.ToolTipText),EVALUATE(SUBSTR(m.This.ToolTipText,2)),m.This.ToolTipText)

ENDDEFINE