Thanks to all that helped me. The below works even better than my previous code. It gets the forecolor right:

*-------------------------------------------------------------------------
*--profileform.setpolicygridcolor()
LOCAL nColumnID
WITH THIS.pgfprofile.pagpolicy.policygrid
   .SETALL('SelectedBackColor', THISFORM.highlightbackcolor)
   .SETALL('SelectedForeColor', THISFORM.highlightforecolor)
   FOR nColumnID = 1 TO .COLUMNCOUNT
      WITH .COLUMNS(nColumnID)
         .DYNAMICBACKCOLOR = "(thisform.GetPolicyGridBackColor('"+.CONTROLSOURCE+"',"+ALLTRIM(STR(nColumnID))+"))"
      .DYNAMICFORECOLOR = "(thisform.GetPolicyGridForeColor('"+.CONTROLSOURCE+"',"+ALLTRIM(STR(nColumnID))+"))"
      .SPARSE = .F.
      ENDWITH
   ENDFOR
   IF USED(.recordsource) .and. !EOF(.recordsource)
      .irecno = RECNO(.recordsource)
   ENDIF
   .REFRESH()
ENDWITH

*-------------------------------------------------------------------------
*--profileform.getpolicygridforecolor()
LOCAL defaultcolorvalue, luValue, lnColorRow
defaultcolorvalue = THIS.gridbackcolor
IF TYPE('tcControlSource') <> "C" .OR. EMPTY(tcControlSource)
	RETURN defaultcolorvalue
ENDIF
tcControlSource = IIF(AT('.',tcControlSource) > 0,UPPER(ALLTRIM(SUBSTR(tcControlSource,AT('.',tcControlSource)))),UPPER(ALLTRIM(tcControlSource)))
IF TYPE('tcColumn') <> "N"
	tcColumn = 0
ENDIF

IF TYPE('this.pgfprofile.pagpolicy.policygrid') = "O" .AND. !ISNULL(THIS.pgfprofile.pagpolicy.policygrid)
	WITH THIS.pgfprofile.pagpolicy.policygrid
		IF USED(.RECORDSOURCE)
			SELECT (.RECORDSOURCE)
			defaultcolorvalue = IIF(RECNO(.RECORDSOURCE)<>.irecno,THIS.gridforecolor,THIS.HIGHLIGHTforeCOLOR)
			DO CASE
				CASE tcControlSource = "PO_STATUS" 
					lnColorRow = ASCAN(_vstatus, EVALUATE(m.tcControlSource), 1,-1,1,2+4+8)
					IF lnColorRow > 0 .AND. !EMPTY(_vstatus[m.lnColorRow,2])
						defaultcolorvalue =  EVALUATE(_vstatus[m.lnColorRow,2])
					ENDIF
			        defaultcolorvalue = IIF(RECNO(.RECORDSOURCE)=.irecno .and. defaultcolorvalue=thisform.gridbackcolor,THIS.HIGHLIGHTFORECOLOR,this.gridforecolor)
				CASE tcControlSource = "PO_SUSP" 
					lnColorRow = ASCAN(_vstatus, PO_STATUS, 1,-1,1,2+4+8)
					IF lnColorRow > 0 .AND. !EMPTY(_vstatus[m.lnColorRow,2])
						defaultcolorvalue =  EVALUATE(_vstatus[m.lnColorRow,2])
					ENDIF
			        defaultcolorvalue = IIF(RECNO(.RECORDSOURCE)=.irecno .and. defaultcolorvalue=thisform.gridbackcolor,THIS.HIGHLIGHTFORECOLOR,this.gridforecolor)
				CASE tcControlSource = "PO_TYPE"
					lnColorRow = ASCAN(_vtype, EVALUATE(m.tcControlSource), 1,-1,1,2+4+8)
					IF lnColorRow > 0 .AND. !EMPTY(_vtype[m.lnColorRow,3])
						defaultcolorvalue = EVALUATE(_vtype[m.lnColorRow,3])
					ENDIF
			        defaultcolorvalue = IIF(RECNO(.RECORDSOURCE)=.irecno .and. defaultcolorvalue=thisform.gridbackcolor,THIS.HIGHLIGHTFORECOLOR,this.gridforecolor)
			ENDCASE
		ENDIF
	ENDWITH
ENDIF
RETURN m.defaultcolorvalue

*-------------------------------------------------------------------------
*--profileform.getpolicygridbackcolor()
LPARAMETERS tcControlSource, tcColumn

LOCAL defaultcolorvalue, luValue, lnColorRow
defaultcolorvalue = THIS.gridbackcolor
IF TYPE('tcControlSource') <> "C" .OR. EMPTY(tcControlSource)
	RETURN defaultcolorvalue
ENDIF
tcControlSource = IIF(AT('.',tcControlSource) > 0,UPPER(ALLTRIM(SUBSTR(tcControlSource,AT('.',tcControlSource)))),UPPER(ALLTRIM(tcControlSource)))
IF TYPE('tcColumn') <> "N"
	tcColumn = 0
ENDIF

IF TYPE('this.pgfprofile.pagpolicy.policygrid') = "O" .AND. !ISNULL(THIS.pgfprofile.pagpolicy.policygrid)
	WITH THIS.pgfprofile.pagpolicy.policygrid
		IF USED(.RECORDSOURCE)
			SELECT (.RECORDSOURCE)
			defaultcolorvalue = IIF(RECNO(.RECORDSOURCE)<>.irecno,THIS.gridbackcolor,THIS.HIGHLIGHTBACKCOLOR)
			DO CASE
				CASE tcControlSource = "PO_STATUS" 
					lnColorRow = ASCAN(_vstatus, EVALUATE(m.tcControlSource), 1,-1,1,2+4+8)
					IF lnColorRow > 0 .AND. !EMPTY(_vstatus[m.lnColorRow,2])
						defaultcolorvalue =  EVALUATE(_vstatus[m.lnColorRow,2])
					ENDIF
			        defaultcolorvalue = IIF(RECNO(.RECORDSOURCE)=.irecno .and. defaultcolorvalue=thisform.gridbackcolor,THIS.HIGHLIGHTBACKCOLOR,defaultcolorvalue)
				CASE tcControlSource = "PO_SUSP" 
					lnColorRow = ASCAN(_vstatus, PO_STATUS, 1,-1,1,2+4+8)
					IF lnColorRow > 0 .AND. !EMPTY(_vstatus[m.lnColorRow,2])
						defaultcolorvalue =  EVALUATE(_vstatus[m.lnColorRow,2])
					ENDIF
			        defaultcolorvalue = IIF(RECNO(.RECORDSOURCE)=.irecno .and. defaultcolorvalue=thisform.gridbackcolor,THIS.HIGHLIGHTBACKCOLOR,defaultcolorvalue)
				CASE tcControlSource = "PO_TYPE"
					lnColorRow = ASCAN(_vtype, EVALUATE(m.tcControlSource), 1,-1,1,2+4+8)
					IF lnColorRow > 0 .AND. !EMPTY(_vtype[m.lnColorRow,3])
						defaultcolorvalue = EVALUATE(_vtype[m.lnColorRow,3])
					ENDIF
			        defaultcolorvalue = IIF(RECNO(.RECORDSOURCE)=.irecno .and. defaultcolorvalue=thisform.gridbackcolor,THIS.HIGHLIGHTBACKCOLOR,defaultcolorvalue)
			ENDCASE
		ENDIF
	ENDWITH
ENDIF
RETURN m.defaultcolorvalue

*-------------------------------------------------------------------------
*--profileform.init()
DODEFAULT()
WITH THIS.pgfprofile.pagpolicy.policygrid
  .ADDPROPERTY('irecno',0)
  THISFORM.gridbackcolor = .backcolor
  THISFORM.gridforecolor = .forecolor
  THISFORM.highlightbackcolor = .highlightbackcolor
  thisform.highlightforecolor = .highlightforecolor
  thisform.highlightstyle = .highlightstyle
  .HIGHLIGHTSTYLE = 0
ENDWITH

*-------------------------------------------------------------------------
*--profileform.pgfprofile.pagpolicy.policygrid.afterrowcolchange()
LPARAMETERS nColIndex
this.irecno = RECNO()
THISFORM.lockscreen = .F.

*-------------------------------------------------------------------------
*--profileform.pgfprofile.pagpolicy.policygrid.beforerowcolchange()
LPARAMETERS nColIndex
THISFORM.lockscreen = .T.