Randy,

Assuming you want to initiate this tiling process from one of the two apps.

to size and position the current app on the left:

with _vfp
   .Top = 0
   .Left = 0
   .Width = sysmetric( 1 ) / 2
   .Height = sysmetric( 2 )
endwith

to size and position the other app on the right:

local lnHwnd

#define SWP_SHOWWINDOW      0x0040

declare integer FindWindow in win32api ;
  string lpClassName, ; && pointer to class name
  string lpWindowName   && pointer to window name

declare integer SetWindowPos IN win32api ;
  integer hWnd,            ; && handle to window
  integer hWndInsertAfter, ; && placement-order handle
  integer X,               ; && horizontal position
  integer Y,               ; && vertical position
  integer cx,              ; && width
  integer cy,              ; && height
  integer uFlags             && window-positioning flags

lnHwnd = FindWindow( .null., "Untitled - Notepad" ) && the other window title is the second app

if ( lnHwnd > 0 )
   SetWindowPos( lnHwnd, 0, sysmetric(1) / 2, 0, sysmetric(1) / 2, sysmetric(2), SWP_SHOWWINDOW )
endif

>David, hi. I am trying to place 2 fvp7 apps on a page without one closing the other.