>Hi ALL,
>
>I have a form with the Window Type property set to 1-Modal. I also have a grid that is displaying the memo field. With the Window Type property set to 1 I am not able to double click on the memo field within the grid in order to edit it.
>
>Is there a way to edit the memo field without changing the Window Type property of the form to 0-Modeless ?
>
>TIA,
>Daniel

Try this:

PUBLIC oform1

oform1=NEWOBJECT("form1")
oform1.Show
RETURN


	**************************************************
*-- Form:         form1 (d:\works\traff\test.scx)
*-- ParentClass:  form
*-- BaseClass:    form
*-- Time Stamp:   10/05/05 08:35:10 PM
*
DEFINE CLASS form1 AS form


	Top = 0
	Left = 0
	Height = 588
	Width = 598
	ScrollBars = 1
	DoCreate = .T.
	ShowTips = .T.
	Caption = "Form1"
	WindowType = 1
	nextdate = (DATE())
	Name = "Form1"


	ADD OBJECT grid1 AS grid WITH ;
		Height = 200, ;
		Left = 19, ;
		Top = 69, ;
		Width = 320, ;
		Name = "Grid1"


	PROCEDURE Load
		CREATE CURSOR cTest (Numtest N(10), MTest M)
		FOR asd = 1 TO 10
		    INSERT INTO cTest VALUES (asd, REPLICATE("Memo", asd))
		NEXT
		GO TOP
	ENDPROC


	PROCEDURE Init
		BINDEVENT(thisform.Grid1.Column2.Text1,"DblClick",thisform,"oEdit",1)
	ENDPROC


	PROCEDURE oedit
		MODIFY MEMO (thisform.Grid1.Column2.ControlSource)
	ENDPROC


ENDDEFINE
*
*-- EndDefine: form1
**************************************************