>Dear Experts
>
>I use following method to export data to Excel
>
>

>SELECT master1
>COPY to C:\gin_exp.xls type xls FIELDS LIKE C*,D* EXCEPT CREDIT,DR_CR
>
>RELEASE ALL LIKE Lo*
>
>loExcel = createobject("Excel.Application")
>loWorkbook = loExcel.workbooks.open('C:\gin_exp.xls')
>loSheet = loWorkbook.sheets(1)
>

>1) How to make sheet rows height=25
>2) How to insert three blank rows at the top of loSheet
>3) How to apply following format on loSheet.Range("A7:C10")
>
>FontColor = RGB(255,0,0)
>FontSize = 12
>FontBold = .T.
>DrawBorder= "xlContinuous:xlMedium")
>
>Please Help

Tariq,
Since I've already replied this elsewhere pasting here too:)

* Line styles
#Define xlContinuous 1
#Define xlDash -4115
#Define xlDashDot 4
#Define xlDashDotDot 5
#Define xlDot -4118
#Define xlDouble -4119
#Define xlSlantDashDot 13
#Define xlLineStyleNone -4142

* Weight
#Define xlHairline 1
#Define xlMedium -4138
#Define xlThick 4
#Define xlThin 2

loExcel = Createobject("Excel.Application")
loExcel.workbooks.Open('C:\gin_exp.xls')
loExcel.Visible = .T.
With loExcel.ActiveWorkbook.ActiveSheet
 *1)  How to make sheet rows height=25
 .UsedRange.RowHeight = 25

 *2)  How to insert three blank rows at the top of loSheet
 .Rows("1:3").Insert()

 *3)  How To apply following Format On loSheet.Range("A7:C10")
 With .Range("A7:C10").Font
  .Color = Rgb(255,0,0)
  .Size  = 12
  .Bold  = .T.
 Endwith
 With .Range("A7:C10").Borders
  .Weight = xlMedium
  .LineStyle = xlContinuous
 Endwith
Endwith

Cetin