set safety off
CREATE TABLE employee (title c(20), birth_date D)
APPEND BLANK
REPLACE employee.title WITH "MANAGER"
REPLACE employee.birth_date WITH DATE()-10680
APPEND blank
REPLACE employee.title WITH "ASST"
REPLACE employee.birth_date WITH DATE()-9680
USE IN employee
Public oForm
oForm = Createobject("myForm")
oForm.Show()

Define Class myForm As Form
  DataSession = 2
  Height = 400
  Width = 600

  Add Object myGrid As Grid With ;
    Height = 400, Width = 600, RecordSource="employee"

  Procedure Load
    Use employee
  Endproc

  Procedure Init
    For Each oColumn In This.myGrid.Columns
      oColumn.DynamicBackColor = ;
        "thisform.MyColColor(["+oColumn.ControlSource+"])"
    Endfor
  Endproc

  Procedure myColColor
    Lparameters tcControlSource
    Local luValue, lnColor
    lnColor = 0xFFFFFF && default white
    luValue = Evaluate(m.tcControlSource)
    Do Case
      Case Lower(m.tcControlSource) = "employee.title"
        If Lower(m.luValue) = "sales manager"
          lnColor = Rgb(255,255,0)
        Endif
      Case Lower(m.tcControlSource) = "employee.birth_date"
        If Year(luValue) % 2 = 0
          lnColor = Rgb(0,255,255)
        Endif
    Endcase
    Return m.lnColor
  Endproc
Enddefine