PROCEDURE GetGuidelines

PRIVATE bSaveSettings,getguidedbf
bSaveSettings = .F.
IF USED('TGUIDELINES')
   USE IN TGUIDELINES
ENDIF
getguidedbf = ALIAS()

IF UseFile('UNDGUIDE','DBGUIDELINES','UGI_ID')

   *---Get Maximum Premium setting
   fMaxPremium = 100000.00
   fFeePremium = 2000.00
   SELECT 0
   SELECT * FROM UNDGUIDE ;
      WHERE UNDGUIDE.UND_EFF <= DATE();
      .AND. UNDGUIDE.UND_OWNER = m.ag_account ;
      INTO CURSOR tGuidelines
   IF USED('TGUIDELINES')
      SELECT tGuidelines
      INDEX ON UGI_ID TAG UGI_ID
      SET ORDER TO TAG UGI_ID
      GO TOP
   ENDIF
   SELECT UNDGUIDE
   GO TOP
   SCAN WHILE !EOF()
      *--Do any special guidelines exist for m.ag_account?
      IF USED('TGUIDELINES') .AND. UNDGUIDE.UND_OWNER <> 1 && only process 1
         LOOP
      ELSE
         *--Too new, OR (not 1 AND not m.ag_account)
         IF UNDGUIDE.UND_EFF > DATE() ;
            .OR. ;
            (UNDGUIDE.UND_OWNER <> 1 .AND. UNDGUIDE.UND_OWNER <> m.ag_account)
            LOOP
         ENDIF
      ENDIF
      irecno = RECNO('UNDGUIDE')
      *--IF tguidelines is used, does a special record exist for this guideline?
      IF USED('TGUIDELINES') .and. INDEXSEEK(UNDGUIDE.UGI_ID,.T.,'tGuidelines','UGI_ID')
         SELECT tGuidelines
      ELSE
         SELECT UNDGUIDE
      ENDIF
      IF UND_EFF <= DATE() .AND. (UND_OWNER = 1 .OR. UND_OWNER = m.ag_account)
         DO CASE
            CASE UGI_ID = UGI_MODE
               gProgramMode = UND_VALUE

            CASE UGI_ID = UGI_RENEWAL
               fc_aprpccr = UND_VALUE

            CASE UGI_ID = UGI_FLEETSUR
               fc_aprpcfl = UND_VALUE

            CASE UGI_ID = UGI_OWNER
               fc_aprpcow = UND_VALUE

            CASE UGI_ID = UGI_AMTFINAPR
               fc_aprpcam = UND_LOGIC

            CASE UGI_ID = UGI_TAXFEE
               m.ag_incltax = UND_LOGIC

            CASE UGI_ID = UGI_MAXPREM
               fMaxPremium = UND_VALUE

            CASE UGI_ID = UGI_MAX6PMT
               IF BETWEEN(UND_VALUE,1,6)
                  m.ag_maxnb6 = UND_VALUE
                  m.ag_maxrn6 = UND_VALUE

                  *TB 12/06/2002
                  IF m.ag_pmtnb6 > m.ag_maxnb6
                     m.ag_pmtnb6 = m.ag_maxnb6
                  ENDIF
                  IF m.ag_pmtrn6 > m.ag_maxrn6
                     m.ag_pmtrn6 = m.ag_maxrn6
                  ENDIF

                  *TB 12/13/2002
                  m.ag_spc6py = m.ag_maxnb6
               ENDIF

            CASE UGI_ID = UGI_ADDFEE
               fFeePremium = UND_VALUE

            CASE UGI_ID = UGI_REQDOB
               m.rf_dob = UND_LOGIC

            CASE UGI_ID = UGI_REQTAXID
               m.rf_taxid = UND_LOGIC

            CASE UGI_ID = UGI_REQPHYADD
               m.rf_phyaddr = UND_LOGIC

            CASE UGI_ID = UGI_REQCONT
               m.rf_contact = UND_LOGIC

            CASE UGI_ID = UGI_DUEOVRIDE
               m.uw_ovradv = UND_LOGIC

            CASE UGI_ID = UGI_MINAPRFAC
               m.ag_ratemin = UND_VALUE

            CASE UGI_ID = UGI_NOADVDATE
               m.uw_noadvdue = UND_LOGIC

            CASE UGI_ID = UGI_PRIME
               m.ag_rate = UND_VALUE
               gPrimeRateIndex = UND_VALUE

            CASE UGI_ID = UGI_FEDRATE
               gFedRateIndex = UND_VALUE

            CASE UGI_ID = UGI_DEFAPR
               gDefaultAPR = UND_VALUE

            CASE UGI_ID = UGI_PRTDRAFT
               ag_sgldrft = UND_LOGIC
               gAllowDrafts = UND_LOGIC

            CASE UGI_ID = UGI_DRFTDAYS
               gDraftsDays = UND_VALUE

               *--TCH 03/02/2006 Issue#4130
            CASE UGI_ID = UGI_DRFT2AGT
               gDraftsToAgt = UND_LOGIC

            CASE UGI_ID = UGI_MINDPCOM
               gMinDpComm = UND_VALUE

            CASE UGI_ID = UGI_HIGHRATE
               gHighPremRate = UND_VALUE

            CASE UGI_ID = UGI_HIGHPREM
               gHighPremAmount = UND_VALUE

            CASE UGI_ID = UGI_INTRORATE
               gIntroRate = UND_VALUE

            CASE UGI_ID = UGI_INTROEXP
               gIntroDate = UND_DATE

            CASE UGI_ID = UGI_INTROMODE
               gIntroMode = UND_VALUE

            CASE UGI_ID = UGI_NO6MONTH
               gNo6Month = UND_LOGIC

            CASE UGI_ID = UGI_RELDATE
               gAllowReleaseDate  = UND_LOGIC
               gReleaseDateAmt  = UND_VALUE

            CASE UGI_ID = UGI_RELDELAY
               gReleaseDateDelay = UND_VALUE

            CASE UGI_ID = UGI_ALLOWRATE
               gAllowAgentRate = UND_LOGIC

            CASE UGI_ID = UGI_AGTRATE
               gAgentRateIndex = UND_VALUE

            CASE UGI_ID = UGI_AGTCEIL
               gAgentRateCeiling = UND_VALUE

            CASE UGI_ID = UGI_CHGRATE
               gAllowChangingAgentRate = UND_LOGIC

         ENDCASE
      ENDIF
      SELE UNDGUIDE
      GOTO irecno
   ENDSCAN

   USE IN UNDGUIDE
   IF USED('TGUIDELINES')
      USE IN TGUIDELINES
   ENDIF

ENDIF
IF !EMPTY(getguidedbf) .and. USED(getguidedbf)
   SELECT (getguidedbf)
ENDIF
RETURN