Hi Marc

Untested code!

>What about this to update master table... is this a good technique (fast and efficient)?
>

If you have an index on cKeyField in cCursorName

m.lcReplace = ""
FOR m.lnCount = 1 TO FCOUNT(m.cCursorName)
  m.lcFieldName = FIELD(m.lnCount,m.cCursorName)
  m.lcReplace = m.lcReplace + m.lcFieldName + " WITH " + ;
    + m.cCursorName + "." + m.lcFieldName + ","
ENDFOR m.lnCount
*Drop the last comma.
m.lcReplace = LEFT(m.lcReplace,LEN(m.lcReplace)-1)

SET ORDER TO (m.cKeyField) IN (m.cCursorName)
SELECT (m.cTableName)
SET RELATION TO (m.cKeyField) INTO (m.cCursorName)
REPLACE ALL &lcReplace. IN (cTableName)

The code you have is replacing one field at a time per locate inside a scan. SET RELATION keeps the two tables in synch. REPLACE ALL does the scan. &lcReplace specifies the source and target fields.

>SELECT (cCursorName)
>SCAN
> SELECT (cTableName)
> LOCATE FOR EVALUATE(cTableName + "." + cKeyField) = EVALUATE(cCursorName + "." + cKeyField)
> IF FOUND(cTableName)
> BEGIN TRANSACTION
> FOR nCount = 1 TO FCOUNT(cCursorName)
> cFieldName = FIELD(nCount, cCursorName) REPLACE (cFieldName) WITH EVALUATE(cCursorName + "." + cFieldName)
> NEXT
> END TRANSACTION
> ENDIF
> SELECT (cCursorName)
>ENDSCAN