Aqui en UT hay artículos, Si buscas en Google hay un monton de links, en msdn.microsoft.com, etc.
Te paso un ejemplo muy simple de gestión (select, insert, delete, update) de una tabla VFP llamada Test01 que tiene dos columnas (codigo, nombre) de clientes. Fácilmente lo puedes pasar a SQL Server u otra DB.

DEFINE CLASS GestionarClientes AS SESSION OLEPUBLIC

	PROCEDURE INIT
		IF NOT USED("Test01")
			USE c:\devtools\vfparena\Test01.DBF IN 0
		ENDIF
	ENDPROC
	
	PROCEDURE DESTROY 
		*-- Cerrar tablas si es necesario
	ENDPROC

	PROCEDURE ListarClientes AS STRING
		LOCAL loXMLAdapter AS XMLADAPTER
		LOCAL lcXMLclientes AS STRING

		loXMLAdapter = CREATEOBJECT("XMLAdapter")

		SELECT * ;
			FROM Test01 ;
			ORDER BY nombre ;
			INTO CURSOR cur_Clientes

		loXMLAdapter.ADDTABLESCHEMA("cur_Clientes")
		loXMLAdapter.UTF8ENCODED = .T.
		loXMLAdapter.TOXML("lcXMLClientes")

		RETURN lcXMLclientes
	ENDPROC


	PROCEDURE AgregarCliente AS Boolean
		PARAMETERS tnCodigo as Number,;
			tcNombre AS String 

		INSERT INTO Test01 (codigo, nombre) VALUES(tnCodigo, tcNombre)
		RETURN .T.

	ENDPROC

	PROCEDURE EliminarCliente AS Boolean
		PARAMETERS tnCodigo as Number 

		DELETE FROM Test01 WHERE codigo = tnCodigo
		RETURN .T.

	ENDPROC

	PROCEDURE ERROR(nError, cMethod, nLine)
		COMRETURNERROR([Método "] + cMethod + ["], MESSAGE())
	ENDPROC

ENDDEFINE

Y aquí y un programa de ejemplo de como consumir ese web services desde VFP

LOCAL loGestionarClientes AS "XML Web Service"
LOCAL loException, lcErrorMsg, loWSHandler
TRY
	loWSHandler = NEWOBJECT("WSHandler",IIF(VERSION(2)=0,"",HOME()+"FFC\")+"_ws3client.vcx")
	loGestionarClientes = loWSHandler.SetupClient("http://CDEV/WSDL_VFP9/GestionarClientes.wsdl", "GestionarClientes", "GestionarClientesSoapPort")
	lcXMLresult = loGestionarClientes.ListarClientes()
	XMLTOCURSOR(STRCONV(lcXMLresult,11),"cur_Clientes",4)
	BROWSE noedit
	USE IN cur_clientes
	
	
CATCH TO loException
	lcErrorMsg="Error: "+TRANSFORM(loException.Errorno)+" - "+loException.Message
	DO CASE
	CASE VARTYPE(loGestionarClientes)#"O"

	CASE !EMPTY(loGestionarClientes.FaultCode)
		lcErrorMsg=lcErrorMsg+CHR(13)+loGestionarClientes.Detail
	OTHERWISE
	ENDCASE
	MESSAGEBOX(lcErrorMsg)
FINALLY
ENDTRY

Espero que te sirva.
Saludos,



>Ok gracias por tus comentarios he realizado 2 proyectos uno de una calculadora y otro proyecto llamado datosremotos con el asistemte de los webservices de Visual Fox Pro 9.0 y han funcionado perfectamente, en concreto lo que me interesa es ver un ejemplo paso a paso para realizar los procesos de insert delete y update en un webservice creado con vusual foxpro ¿conoces algun link donde pudiera encontrar un ejemplo acerca de esto?