Hi Carlos and Juri!
Following your ideas, I developed a function to convert an ISO-8859-1?Q? string that works correctly:

Function CharSetConv
   Lparameters lcText
   Local lcNewText, llConvert, lnPos, lcNewChar
   lcNewText = ""
   llConvert = .F.
   For lnPos=1 To Len(lcText)
      If Upper(Substr(lcText,lnPos,15)) == "=?ISO-8859-1?Q?"
         lnPos = lnPos + 14
         llConvert = .T.
         Loop
      Endif
      If llConvert
         Do Case
            Case Substr(lcText,lnPos,2) == "?="
               lnPos = lnPos + 1
               llConvert = .F.
               Loop
            Case Substr(lcText,lnPos,1) = "="
               lcNewChar = Evaluate("Chr(0x"+Substr(lcText,lnPos+1,2)+")")
               lcNewText = lcNewText + lcNewChar
               lnPos = lnPos + 2
               Loop
            Case Substr(lcText,lnPos,1) = "_"
               lcNewText = lcNewText + Space(1)
               Loop
         Endcase
      Endif
      lcNewText = lcNewText + Substr(lcText,lnPos,1)
   Endfor
   Return lcNewText
Endfunc

But now appear strings encoded in utf-8?b?, utf-8?q?, iso-8859-1?b?, ...

Another idea on how to convert these strings?