>I am porting an Access application over to VFP. The Access code has a section which executes a query (SQL SELECT) and copies it to the clipboard, then pastes the query into a Word document where it appears as a table. Is this type of action possible in VFP? That is: how would you get the results of a SELECT into the clipboard so it can be pasted into the Word doc?
>
>Thanks for any hints. (or actual code)

Don,
There are multiple ways as always. One of them:

#Define wdSeparateByCommas  2
#Define wdSeparateByDefaultListSeparator  3
#Define wdSeparateByParagraphs  0
#Define wdSeparateByTabs  1

#Define wdTableFormatClassic1  4
#Define wdTableFormatColorful1  8
#Define wdTableFormatColorful2  9
#Define wdTableFormatColorful3  10
#Define wdTableFormatContemporary  35
#Define wdTableFormatElegant  36

lcTempFile = Sys(2015)+'.tmp'
Use employee
Copy To (lcTempFile) Fields First_Name, Last_Name, Title Type Delimited With Tab
_Cliptext = "First Name"+Chr(9)+"Last_Name"+Chr(9)+"Title"+;
  Chr(13)+Chr(10)+Chrtran(Filetostr(lcTempFile),'"','')
Erase (lcTempFile)

oWordDocument=Createobject("word.application")	&& Create word object
With oWordDocument
  .documents.Add	&& New file
  With .ActiveDocument.Range
    .Paste      && Paste VFP data
    .ConvertToTable(wdSeparateByTabs,,,,wdTableFormatColorful2,,,,,,.F.,.F.,.F.) && Convert to table
  Endwith
  .Visible = .T.
Endwith

Cetin