>Dear Sir,
>

>BC25='D:\C2007\TABLES\BACKUP' && Target
>CD 'D:\C2007\TABLES' && Source to copy
>RUN n/7 XCOPY *.DBF &bc25 /y /q
>CD..
>

>The above codes work fine outside exe.
>When I run it from exe, they do nothing.
>Also every time a DOS window appears, I do not want to show that.
>
>Please help

Tariq,

Try to do it using this function

procedure RunShellScript
lparameters tcCommand, tlSilentMode, tcRetVal

if empty(m.tcCommand)
	return
endif

local oShell, llError, loException, lnErrorCode
llError = .f.
try
	oShell = createobject("WScript.Shell")
catch to loException
	if m.tlSilentMode
		tcRetVal = "Run-time error: WScript.Shell Object is not Found"
	else
		=messagebox("Run-time error: WScript.Shell Object is not Found")
	endif
	llError = .t.
endtry
if m.llError <> .t.
	try
		lnErrorCode = oShell.run(m.tcCommand, 0,.t.) && SW_SHOW_HIDDEN 0,SW_SHOW_NORMAL 1,SW_SHOW_MINIMIZED 2,SW_SHOW_MAXIMIZED 3
		if m.lnErrorCode <> 0
		   tcRetVal = "Error in running shell command. Error Code: " + transform(m.lnErrorCode)
		endif   
	catch to loException
		if m.tlSilentMode
			tcRetVal = "Run-time error: WScript.Shell: " + ;
				m.tcCommand + chr(13) + chr(10) + Log_Error(m.loException)
		else
			=messagebox("Run-time error: WScript.Shell: " + m.tcCommand)
		endif
		llError = .t.
	endtry
endif
release oShell

return !m.llError

Also please check your private messages in UT.