>Add them to top and bottom then. Just insert into appropriate places within textmerge
>
>Dear sir,
>
>I do not know how and where to add?
>
>Please help again
You are not helping me much cutting off my previous replies:(
Select c.company, ;
o.order_date, o.order_id, ;
e.First_Name-(' '+e.Last_Name) As Employee, ;
oi.line_no, p.prod_name, ;
oi.unit_price, oi.quantity ;
FROM testdata!customer c ;
INNER Join testdata!orders o ON c.cust_id = o.cust_id ;
INNER Join testdata!Employee e ON o.emp_id = e.emp_id ;
INNER Join testdata!orditems oi ON o.order_id = oi.order_id ;
INNER Join testdata!products p ON oi.product_id = p.product_id ;
order By 1,2,3,5 ;
INTO CURSOR myCursor ;
nofilter
TEXT TO m.lcHeader noshow
<html>
<head>
<title>My Table</title>
<STYLE>
TH { font-family: Times, serif;
background-color: #000080;
color: #FFFFFF;
text-align: center;
font-size: X-Large;
}
.f0 { font-size: 10pt; font-family: Arial; text-align=right; }
</STYLE>
</head>
<body>
Pakistan Television Corporation<br>
From 01-07-2007 to 21-03-2007<br><br>
ENDTEXT
SET TEXTMERGE TO memvar m.lcHeader ADDITIVE noshow
SET TEXTMERGE on
\<table border='1' cellspacing=0>
\ <tr>
FOR ix=1 TO FCOUNT()
\ <th><<PROPER(FIELD(m.ix))>></th>
ENDFOR
\ <tr>
SCAN
\ <tr>
FOR ix=1 TO FCOUNT()
DO CASE
CASE TYPE(FIELD(m.ix)) = 'Y'
\ <td class='f0'>
\\<<TRANSFORM(EVALUATE(FIELD(m.ix)),'@R $$9,999,999')>>
CASE TYPE(FIELD(m.ix)) = 'N'
\ <td class='f0'>
\\<<TRANSFORM(EVALUATE(FIELD(m.ix)),'@R 99,999,999')>>
otherwise
\ <td>
\\<<EVALUATE(FIELD(m.ix))>>
endcase
\ </td>
ENDFOR
\ <tr>
endscan
\</table>
\<br>
\Accountant signature
\</body>
\</html>
SET TEXTMERGE to
SET TEXTMERGE offCetin
