Hi Hans,

You can use FoxTools to access the command window and set its font. Here's the basic code that should get you started. See George's Extended Foxtools Help File #9333 for more info.

LOCAL ARRAY laEnv[25]
SET LIBRARY TO FoxTools ADDITIVE

ACTIVATE WINDOW Command
lnwhandle  = _WonTop()
lnResult = _EdGetEnv( lnwHandle, @laEnv )
* Make sure that call succeed and the handle belongs to the Command WIndow
IF lnResult <> 0 AND laEnv[25]=0
	* Font Name
	laEnv[22] = "Consolas"
	* Font Size
	laEnv[23] = 13
	IF _EdSetEnv( lnwHandle, @laEnv ) <> 0 
		? "Success"
	ELSE
		? "Could not set Command Window Font"
	ENDIF	
ELSE
	? "Could not get Command Window handle"
ENDIF	

>
>using _SCREEN I can set properties of the main Visual FoxPro window and manipulate the main Visual FoxPro window as an object. Is there anything available to do something similar for / with the Command Window?
>
>I want to set some properties, mainly FontName and FontSize programmatically. (I know how to do it manually.)
>
>I have checked the FoxUser.dbf, ID = "WINCMD", but did not find anything, where for instance I could place something like WINCMD.FontName = ..
>