lcWindStandard = WEXIST('standard')

IF lcWindStandard
      HIDE WINDOW standard
ENDIF

LOCAL oPreviewForm
oPreviewForm = createOBJECT('PreviewForm')
REPORT FORM test TO PRINTER PROMPT WINDOW PREVIEWFORM PREVIEW
oPreviewForm.Release
IF lcWindStandard
      SHOW WINDOW standard
ENDIF
RETURN

DEFINE CLASS previewform AS form

      Height = 500
      Width = 700
      Desktop = .F.
      ShowWindow = 1
      ScrollBars = 3
      DoCreate = .T.
      AutoCenter = .T.
      BorderStyle = 1
      Caption = "Print Preview Window"
      ControlBox = .F.
      Closable = .F.
      MinButton = .F.
      MaxButton = .T.
      Movable = .F.
      WindowType = 0
      WindowState = 1
      AlwaysOnTop = .F.
      onkeyctrlf10 = "''"
      Name = "previewform"

      PROCEDURE QueryUnload

            lcoldctrlf10setting = THISFORM.onkeyctrlf10
            IF !EMPTY(lcoldctrlf10setting)
                  ON KEY LABEL CTRL+F10 &lcoldctrlf10setting
            ENDIF
      ENDPROC

      PROCEDURE Init
            DODEFAULT()
            THISFORM.onkeyctrlf10 = ON('KEY LABEL','CTRL+F10')
            ON KEY LABEL CTRL+F10
            THIS.SHOW()
            CLEAR TYPEAHEAD
      ENDPROC

      PROCEDURE Deactivate
            DODEFAULT()
            IF WEXIST('Report Designer')
                  MOUSE DBLCLICK AT -0.1,0.1 WINDOW "Report Designer"
            ENDIF
            IF WEXIST('Print Preview')
                  MOUSE DBLCLICK AT -0.1,0.1 WINDOW "Print Preview"
            ENDIF
            keyboard "{ctrl+f10}"
      ENDPROC

ENDDEFINE

>>>>>Morning All,
>>>>>
>>>>>In the past few days, the preview window for the reports is not displaying. There is a flash as the report toolbar appears and disappears, but the preview window never appears. Does anyone know what is causing this, and how do I fix it?
>>>>>
>>>>>Thanks
>>>>
>>>>Are you sure you do have DATA in the cursor that drives the report?
>>>
>>>I posted my question prematurely. I had added a IN WINDOW clause to the REPORT FORM line, but forgot to make the window visible. This prevented the report from be displayed and the report esitted immediately.
>>
>>Thanks. I didn't read the title of your post carefully, sorry :(
>
>no problem.
>
>DO you have any ideas on how to maximize the preview window without using the IN WINDOW clause?