I thought it was your intention but looks like you needed something else:

PUBLIC oForm
oForm = CREATEOBJECT('myForm')
oForm.Show

DEFINE CLASS myForm as Form
    datasession = 2
    Height = 200
    Width = 600
    PROCEDURE load
        USE (_samples+'data\customer')
    endproc

    ADD OBJECT myGrid as grid WITH height=200,width=600

    procedure init
        WITH this.myGrid.Columns(2)
            .NewObject('text2','myTextBox')
            .CurrentControl = 'text2'
            .Sparse = .f.
            .text2.visible = .t.
        ENDWITH
        WITH this.myGrid.Columns(3)
            .NewObject('myButton','myButton')
            .CurrentControl = 'myButton'
            .Sparse = .f.
            .myButton.Visible = .t.
        endwith
    endproc
ENDDEFINE

DEFINE CLASS myTextBox as textbox
    PROCEDURE when
        RETURN .f.
    ENDPROC
enddefine

DEFINE CLASS myButton as CommandButton
    PROCEDURE Click
        WAIT WINDOW "You clicked me" TIMEOUT 3
    ENDPROC
    Procedure When
        RETURN MDOWN()
    Endproc
enddefine

Cetin

>Hi Cetin.
>Dis a bit of experimenting:
>If I set Enabled to .f. for the column, the column becomes disbled, but I cannot click into it.
>
>If I do a Return .f. in rhe When event of the control,it in effect becomes disbaled but I cannot click i nit either (nothin happens)
>
>I have Commandbuttons in the Columns, doe this matter ?
>
>Regards,
>Gerard
>
>
>
>
>>>Hi.
>>>I have a Gris with a few columns, and I want the default behaviour of some of the columns to be Tbastop = .f., so the user should not land in them.
>>>
>>>I notice there is not a Tabstop control for the column itselef, so I set the Tabstop of the Control in the column to .F., however, the user still lands in the column, and the TabStop propert seems to make no diffeence.
>>>
>>>Is there a way of 'Jumping' over a column ?
>>>
>>>Regards,
>>>Gerard
>>
>>Gerard,
>>Either set enabled = .f. for the column or return .f. from when event of its control. Both however wouldn't prevent you form focusing to it with mouse.
>>Cetin