>Hi !
>can any one tell me how to create sql database tables and indexs
>with vfp programmatically into the sql server or msde ?

Here is a sample:

Local lnHandle, lcDatabaseName
lcDatabaseName = "myTestData"
lnHandle=SQLStringConnect('DRIVER=SQL Server;SERVER=.;Trusted_connection=Yes')
If SQLExec(lnHandle, "create database "+lcDatabaseName) < 0
  Do errHand
  Return
Endif
mySQLExec(lnHandle, "use "+lcDatabaseName)
mySQLExec(lnHandle, ;
  "create table myTable"+;
  " (myID int not null, myDate datetime not null)")
SQLPrepare(lnHandle, "insert into myTable (myID, myDate) values (?m.ix,?m.myDate)")

For ix=1 to 10
  m.myDate = Date()+m.ix
  SQLExec(lnHandle)
Endfor
mySQLExec(lnHandle, "select * from myTable","myCheck")
SQLDisconnect(lnHandle)
Browse

Function mySQLExec
Lparameters tnHandle, tcSQL, tcCursorName
tcCursorName = iif(empty(tcCursorName),'',tcCursorName)
If SQLExec(tnHandle,tcSQL,tcCursorName) < 0
  Do errHand with tcSQL
Endif

Function errHand
Lparameters tcSQL
lcError=tcSQL+chr(13)
Aerror(arrCheck)
For ix=1 to 7
  lcError = lcError+trans( arrCheck [ix])+ chr(13)
Endfor
Messagebox(lcError,0,'Error def.')

PS: You might also do this:
text to m.lcSQL noshow
--SQL commands here as you would write in SQL analyzer
endtext

SQLexec(m.lnHandle,m.lcSQL)

Cetin