Hi Aritra,

Full screen for form or main window?

loo=CREATEOBJECT("_fullscreen")
loo.SetFullScreen()
wait window "FullScreen mode" time 3
loo.SetFullScreen()

DEFINE CLASS _fullscreen AS Custom
   FullScreenMode=0
   FullScreen=.F.
   _FullScreen_SB=""
   _FullScreen_WS=0
   _FullScreen_Left=0
   _FullScreen_Top=0
   _FullScreen_Width=0
   _FullScreen_Height=0
   _FullScreen_PV=.F.

   DIME _aFullScreen_tlb(1)

   PROCEDURE Init()
      DECLARE INTEGER LockWindowUpdate IN USER32.DLL Integer
      DECLARE INTEGER MoveWindow IN USER32.DLL INTEGER,INTEGER,INTEGER,INTEGER,INTEGER,INTEGER
   ENDPROC

   PROCEDURE SetFullScreen(llFS) && Nastaveni fulscreen modu
      LOCAL lii,liy
      =LockWindowUpdate(_vfp.hwnd)&& Zamkne celý desktop
      
      IF !This.FullScreen
         This._FullScreen_Left=_vfp.Left
         This._FullScreen_Top=_vfp.Top
         This._FullScreen_Width=_vfp.Width
         This._FullScreen_Height=_vfp.Height
*         This._FullScreen_PV=tlbPanel.Visible


         This._FullScreen_SB=SET("STATUS BAR")
         This._FullScreen_WS=_Screen.WindowState

         _Screen.Move(-_Screen.Width-100,0)

         liy=0
         IF _Screen.FormCount>0
            DIME This._aFullScreen_tlb(_Screen.FormCount,6)
         ENDIF
         FOR lii=_Screen.FormCount TO 1 STEP -1
             IF UPPER(_Screen.Forms(lii).BaseClass)=="TOOLBAR" AND _Screen.Forms(lii).Visible
                liy=liy+1
                This._aFullScreen_tlb(liy,1)=_Screen.Forms(lii)
                =_Screen.Forms(lii).Hide()
             ENDIF
         NEXT
         IF liy>0
            DIME This._aFullScreen_tlb(liy,6)
         ELSE
            DIME This._aFullScreen_tlb(1)
            This._aFullScreen_tlb(1)=.NULL.
         ENDIF

         _Screen.TitleBar =0
         _Screen.BorderStyle=0
         IF This._FullScreen_SB="ON"
            SET STATUS BAR OFF
         ENDIF
         PUSH MENU _msysmenu
         HIDE MENU _msysmenu
         IF _Screen.WindowState#2
            _Screen.WindowState=2
         ENDIF
         STORE .F. TO _Screen.MaxButton,_Screen.MinButton
         This.FullScreen=.T.
      ELSE
         POP MENU _msysmenu
         SHOW MENU _msysmenu
*!*             IF This._FullScreen_PV
*!*                =ShowMainPane(.T.)
*!*             ENDIF
         =LockWindowUpdate(_vfp.hwnd)&& Zamkne celý desktop
         _Screen.TitleBar =1
         _Screen.BorderStyle=3

         IF !ISNULL(This._aFullScreen_tlb)
            FOR lii=1 TO ALEN(This._aFullScreen_tlb,1)
                This._aFullScreen_tlb(lii,1).Show()
            NEXT
         ENDIF

         IF This._FullScreen_SB="ON"
            SET STATUS BAR ON
         ENDIF
         =MoveWindow(_vfp.hwnd,This._FullScreen_Left,This._FullScreen_Top,This._FullScreen_Width,This._FullScreen_Height,1)  && přesun screenu pomocí winapi
         _Screen.WindowState=This._FullScreen_WS
         STORE .T. TO _Screen.MaxButton,_Screen.MinButton
         _Screen.Resize()
         This.FullScreen=.F.
      ENDIF
      =LockWindowUpdate(0)&& Odemkne celý desktop
   ENDPROC
enddefine

>Hi friends
>
>I like to develop a customized software where the main form will be Full Screen ( not maximized).
>
>I like the Form to be Full screen Size as it happens when we choice Full Screen in Windows Media Player ie. even the start button doesn't appear on screen and we can exit the application by pressing some function key like F10.
>
>It will be very usefull for me if I get some solution.
>
>Thanks
>
>Aritra