Manuel,

>Gracias Hugo, por responder.

De nada, espero poder ayudarte

>¿Si pulso sobre la pestaña de la página 4 de un PageFrame, se dispara el evento PageFrame.Page4.Activate?

Si

>
>¿Si desde un botón ejecuto este código
>
>

>Thisform.Pageframe1.Page4.Setfocus
>

>
>se dispara el evento PageFrame.Page4.Activate?

No, lo que deberías hacer es, en vez de SetFocus, algo así como

thisform.pageframe1.ActivePage = thisform.pageframe1.page4.pageorder

te paso un ejemplo sencillo para ver si te ayuda

loForm				= Createobject('myForm')
loForm.Show(1)

define class myForm as Form
	add object myPageFrame as myPageFrame with Left=0, Top=0, width=250, height=200
	add object myButton as myButton with left = 251, width=100, Top=0, height=24, caption='Activate Page 2'
enddefine

define class myPageFrame as PageFrame
	add object myPage1 as myPage
	add object myPage2 as myPage
	add object myPage3 as myPage
	add object myPage4 as myPage
	
	function init() as Boolean
		this.myPage4.PageOrder = 2 && solo para demostrar
	endfunc
enddefine

define class myPage as Page
	procedure activate
		wait window this.Name + ' activated' nowait
		this.Refresh()
	endproc
enddefine

define class myButton as CommandButton
	procedure click
		thisform.myPageFrame.ActivePage = thisform.myPageFrame.myPage2.PageOrder
	endproc
enddefine

>
>Gracias por tu ayuda y saludos cordiales.
>
>Manuel Tovar
>Barranquilla - COLOMBIA