>I am tring to find a way to check for a string within a string but what I have came uo with is strill not working every time.
>
>I am using the AT() function but this fails if my:
>
>search expression is revJ
>and searched expression is 855956-401 revJ2
>
>J and J2 are two different revision levels.
>
>Sometimes searched expression can be more complex like:
>855965-401 revJ2, 855965-403 revJ2, 855965-405 revJ2
>
>Any ideas?

Steven,
I think using regular expressions would be easier than trying to do with VFP functions. As I understand you want to find "revJ" as a word. ie:

lcString = "855965-401 revJ2, revJ 85revJ 5965-403 and revJ, revJ2, 855965-405 revJ2"
oRX = Createobject("VBScript.RegExp")
With oRX
  .Pattern = "\brevJ\b"
  .IgnoreCase = .F.
  .Global = .T.
  Local loMatches
  loMatches = .Execute(m.lcString)
ENDWITH
_screen.FontName = "Courier New"
clear
? m.lcString
For Each loMatch In loMatches
	? PADL("^",loMatch.firstIndex+1)
*    ? loMatch.firstIndex + 1,loMatch.Value
ENDFOR

** And you could replace all matches with something else unique
** This one is using the pattern above
NewString = oRX.Replace(m.lcString, REPLICATE("%",LEN("revJ")))
? m.lcString
? m.NewString

** Or simply ask if exists with Test method.
? oRX.Test(m.lcString)

Cetin