>Hello Experts!
>
>I am trying to place a signature (biometric data), stored in a memo fields, on a VFP report. The signature capture software recommended to to place an ActiveX control (SigPlus - from Toppaz Su=ystems) on the report and then bind the signature data (memo field) to it. Is it possible to place an ActiveX control on a report ?. Can someone help me please....
>
>Raz

We do the same thing when printing Invoices. The following code extracts the signiture from the memo field and generates a bitmap by known name. In the report simply reference the known bitmap name as an image.

oSigSign = CREATEOBJECT("SIGPLUS.SigPlusCtrl.1")

DELETE FILE Signature*.bmp

WITH oSigSign
	.OpaqueMode		= .T.
	.BACKCOLOR		= RGB(255,255,255)
	.SigCompressionMode	= 0
	.EncryptionMode 	= 0
	.ImageXSIze 		= 500
	.ImageYSize		= 50
	.ImagePenWidth		= 3
	.JustifyMode		= 5
	.JustifyX		= 10
	.JustifyY		= 10
	.TabletResolution	= 410
	.TabletLogicalXsize	= 2000
	.TabletLogicalYsize	= 600
	.TabletMode		= 6
	.TabletType		= 6
	.TabletXStart		= 400
	.TabletXStop		= 2400
	.TabletYStart		= 3500
	.TabletYStop		= 950
	.ZoomPower		= 1
	.ImageFileFormat 	= 1 && Uncompressed BMP

	TRY

		SELECT myTbl

		.ClearTablet()
		locFileName 	= "Signature.bmp"
		CLEAR RESOURCES (locFileName)   && fox from see the last bmp in memory
		.SigString 	= ALLTRIM(myTbl.MemoField)
		.WriteImageFile(locFileName)
		llResult = FILE(locFileName)

	CATCH
	ENDTRY
ENDWITH
RETURN llResult

It is not in this code, but we also zip the text signiture before store it in the memo field, and unzip before generating the bitmap. We found the memo file grow vary rapid otherwise. Do not use the comperation biult in the Topaz control. You will loose the clarity of the signiture.

Hope it helps.