>Anyone can recommend a tool that would give me the biggest files on my HD?
>
>I use Vista

How about this to get a directory of all files w/path/size/attributes..

DO getfilelist WITH 'c:\*.*','DHS'
**********************************************
Procedure Getfilelist
LPARAMETERS lcFileSkeleton,lcAttributes,llKeepDirectory

DO RecurseDirectories WITH lcFileSkeleton,lcAttributes,llKeepDirectory

WAIT clear

IF USED('filedirectory')
INDEX on filepath TAG filepath
INDEX on filename TAG filename
INDEX on filesize TAG filesize
ENDIF

SET ORDER to FILEPATH && FILEPATH

GO top

BROWSE nowait

RETURN

****************************************

PROCEDURE RecurseDirectories
LPARAMETERS lcFileSkeleton,lcAttributes,llKeepDirectory

LOCAL ARRAY laDirectory[1,1]
LOCAL lnFileCount as Integer
LOCAL lnCounter as Integer
LOCAL lcCurrentPath as varchar(200)

IF EMPTY(llKeepDirectory)
llKeepDirectory = .F.
endif

IF (!llKeepDirectory) AND FILE('FileDirectory.dbf')
USE IN SELECT('filedirectory')
DELETE FILE filedirectory.dbf
ENDIF

IF !llKeepDirectory
CREATE TABLE FileDirectory (FilePath varchar(200),FileName varchar(100), FileSize integer, ModiDate date, ModiTime char(16), FileAttr char(6))
endif

IF EMPTY(lcFileSkeleton)
lcFileSkeleton = '*.*'
ENDIF

IF EMPTY(lcAttributes)
lcAttributes = 'DHS'
endif

lnFileCount = ADIR(laDirectory,lcfileSkeleton,lcAttributes)
lcCurrentPath = JUSTPATH(lcFileSkeleton)
WAIT 'Processing: '+ALLTRIM(lcCurrentpath)+'..hang on!' WINDOW nowait

IF lnFileCount > 0


FOR lnCounter = 1 TO lnFileCount

IF !EMPTY(STRTRAN(laDirectory[lncounter,1],'.',''))

IF 'D' $ laDirectory[lncounter,5] && directory - need to recursively call!

RecurseDirectories(ADDBS(lcCurrentPath)+ADDBS(TRIM(laDirectory[lncounter,1]))+justfname(lcFileSkeleton),lcAttributes,.T.)

ELSE

INSERT INTO FileDirectory (FilePath,FileName,FileSize,ModiDate,ModiTime,FileAttr) VALUES (lcCurrentPath,laDirectory[lncounter,1],laDirectory[lncounter,2],laDirectory[lncounter,3],laDirectory[lncounter,4],laDirectory[lncounter,5])

ENDIF

endif

endfor

ENDIF && lnFileCount > 0

RETURN && recursedirectories

return && getfilelist