Add NODEFAULT to Spinner's KeyPress to disable keyboard input.

PUBLIC oform1

oform1=NEWOBJECT("form1")
oform1.Show
RETURN

DEFINE CLASS form1 AS form

	DoCreate = .T.
	Caption = "Form1"
	Name = "Form1"

	ADD OBJECT spinner1 AS spinner WITH ;
		Height = 24, ;
		Left = 48, ;
		Top = 60, ;
		Width = 28, ;
		Name = "Spinner1"

	ADD OBJECT text1 AS textbox WITH ;
		Height = 23, ;
		Left = 144, ;
		Top = 60, ;
		Width = 100, ;
		Name = "Text1"

	PROCEDURE spinner1.KeyPress
		LPARAMETERS nKeyCode, nShiftAltCtrl
		NODEFAULT
	ENDPROC


	PROCEDURE spinner1.Init
		* From Message #1313781
		This.Width = Sysmetric(5) + 4
	ENDPROC

	PROCEDURE spinner1.InteractiveChange
		Thisform.Text1.Value = This.Value
	ENDPROC

ENDDEFINE

>I need to change the value of 'something' but using a scrollbar.
>I've tried the Microsoft Forms 2.0 ScrollBar
>activeX control but I can't find the property from where I can
>get the value. There is no value property.
>There is a Change event that fires when its value change.
>Question: Can I implement a Scrollbar by other way?
>If not possible I can use a spinner but I would
>like it has no capacity to receive data entered from keyboard.
>Just with the mouse.
>Is it possible to achieve this?
>Thanks!