>A better alternative would be to use CDO. With CDO you do not need to work-around the security patch.

Thank you all !!!!!
I realized that CDO is what I need. No need to mess with outlook.
After much research (I don't remember the sources though, sorry) this is what works for me:
(i hope this will work for all workstations, whether or not they have outlook or outlook express)

lcTo="username@mydomainname"
lcFrom="System"
lcSubject="CDO Mail"
lcTextBody="Sending email with CDO."
lcHTMLBody=""

*Define mail server name here
#DEFINE D_MailServerName "mail.mydomainname"

loMsg=CREATEOBJECT("CDO.Message")
IF VARTYPE(LoMsg)="O"
	liConfig=CREATEOBJECT("CDO.Configuration")
	IF VARTYPE(liConfig)="O"
		loFields=liConfig.Fields
		WITH loFields
			.Item("http://schemas.microsoft.com/cdo/configuration/sendusing")=2
			.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver")=D_MailServerName
			.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport")=25
			.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout")=90
			.Update
		ENDWITH
		
		*Define message properties
		WITH loMsg
			.Configuration=liConfig
			.To=lcTo
			.From=lcFrom
			.Subject=lcSubject
			
			*Use HTML Body text, if provided, otherwise use Text Body
			IF ! EMPTY(lcHTMLBody)
				.HTMLBody=lcHTMLBody
			ELSE
				.TextBody=lcTextBody
			ENDIF
			.Send
		ENDWITH
	ENDIF
ENDIF