>This seems complex but am looking for ideas. I want to dump a daily vfp table that produces 1 column of data with x number of rows.
>I want to import/append this 1 column into excel in the next available blank column. so each day the available blank column progresses such as A,B,C.....AA,BB,CC etc.

Actually it's easy Tim. ie:

rand(-1)
create cursor xx (myData c(10))
for ix = 1 to int(rand()*20)
	insert into xx values (textmerge('Day <<m.ix>>'))
endfor
select * from xx into array arrData


lcXLS = 'c:\MyFolder\myDays.xls'

oExcel = createobject('Excel.Application')
oExcel.visible = .t.
if file(m.lcXLS)
	oExcel.Workbooks.open(m.lcXLS)
	with oExcel.ActiveWorkBook.ActiveSheet
	 .range(;
		.Cells(1,.UsedRange.columns.count+1), ;
		.Cells( alen(arrData),.UsedRange.columns.count+1)).value = getArrayRef('arrData')
	endwith
else
	oExcel.Workbooks.add
	oExcel.ActiveWorkBook.saveas(m.lcXLS)
	with oExcel.ActiveWorkBook.ActiveSheet
	  .range(;
		.Cells(1,1), ;
		.Cells( alen(arrData),1)).value = getArrayRef('arrData')
	endwith
endif
oExcel.ActiveWorkBook.save

function getArrayRef(tcArrayName)
	return @&tcArrayName

Cetin