As far as I know, Microsoft has released 7 different builds of VFP9 (3 of them hotfixes). VFP9 SP0 ("RTM") was dated 2004.12.13, build number 2412. The latest build I know of is the KB952548 hotfix, 2008.06.03, build number 6602.

I wrote a program with build information that generates some statistics (see below). Over the full time span, the build rate is a little over 3 per day. Most of the build rates between builds are close to this as well, a figure this steady implies an automated process rebuilding/recompiling the source several times per day whether any code changes have been made or not.

The significant exceptions are:

- between SP2 v2 and KB 948528, where the build rate dropped to 2.30/day (implies relative inactivity)
- between KB948528 and KB952548, where it spiked to 14.95/day (implies that KB952548 was a hard bug to fix)

Anyone know of any other interim or later builds, with build numbers and file dates?

It would be nice to have the hotfixes available somewhere, like on ProLib rather than having to go through the hassle of MS Support to get them.

* Uses CAST(), requires VFP9 ;)
CREATE CURSOR VFP9Blds ( BldName C( 10 ), BldNum I, BldDate D )

INSERT INTO VFP9Blds ( BldName, BldNum, BldDate ) ;
	VALUES ( "SP0 (RTM)", 2412, {^2004-12-13} )

INSERT INTO VFP9Blds ( BldName, BldNum, BldDate ) ;
	VALUES ( "KB897575", 2826, {^2005-04-26} )

INSERT INTO VFP9Blds ( BldName, BldNum, BldDate ) ;
	VALUES ( "SP1", 3504, {^2005-11-04} )

INSERT INTO VFP9Blds ( BldName, BldNum, BldDate ) ;
	VALUES ( "SP2 v1", 5721, {^2007-09-21} )

INSERT INTO VFP9Blds ( BldName, BldNum, BldDate ) ;
	VALUES ( "SP2 v2", 5815, {^2007-10-15} )

INSERT INTO VFP9Blds ( BldName, BldNum, BldDate ) ;
	VALUES ( "KB948528", 6303, {^2008-05-14} )

INSERT INTO VFP9Blds ( BldName, BldNum, BldDate ) ;
	VALUES ( "KB952548", 6602, {^2008-06-03} )

* Generate some statistics:
* Column NewBldsSP0 is number of new builds since SP0
* Column DaysSP0 is number of days since build of SP0
* Column BldRateSP0 is average Builds/Day since SP0
* Column NewBldsLatest is number of new builds since prior build
* Column DaysLatest is number of days since prior build
* Column BldRateLatest is average Builds/Day since prior build

SELECT ;
  * ;
  , CAST( 0 AS I ) AS NewBldsSP0 ;
  , CAST( 0 AS I ) AS DaysSP0 ;
  , CAST( 0 AS N( 5, 2 ) ) AS BldRateSP0 ;
  , CAST( 0 AS I ) AS NewBldsLatest ;
  , CAST( 0 AS I ) AS DaysLatest ;
  , CAST( 0 AS N( 5, 2 ) ) AS BldRateLatest ;
  FROM VFP9Blds ;
  INTO CURSOR VFP9Stats ;
  ORDER BY BldNum ;
  READWRITE

GO TOP IN VFP9Stats

m.BldSP0 = VFP9Stats.BldNum
m.DateSP0 = VFP9Stats.BldDate

m.BldPrior = m.BldSP0
m.DatePrior = m.DateSP0

SKIP 1 IN VFP9Stats
SCAN REST
	REPLACE ;
		NewBldsSP0 WITH BldNum - m.BldSP0 ;
		, DaysSP0 WITH BldDate - m.DateSP0 ;
		, BldRateSP0 WITH ( ( BldNum - m.BldSP0 ) / ( BldDate - m.DateSP0 ) ) ;
		, NewBldsLatest WITH BldNum - m.BldPrior ;
		, DaysLatest WITH BldDate - m.DatePrior ;
		, BldRateLatest WITH ( ( BldNum - m.BldPrior ) / ( BldDate - m.DatePrior ) ) ;
		NEXT 1 ;
		IN VFP9Stats
	
	m.BldPrior = VFP9Stats.BldNum
	m.DatePrior = VFP9Stats.BldDate

ENDSCAN

GO TOP IN VFP9Stats
BROWSE NOWAIT