Hi Matt,

> It sounds complicated, but I'll see if I can find some code samples.

It's not. Here's a sample that prints the summary band at the end of the page. You need to change the value for nSummaryHeight to specify how far down from the button of the page the summary band should start.You could get these values automatically by using two passes and recording the positions and dimensions of the summary band in the first pass.

ox = CreateObject("Demo")
ox.ListenerType = 1
Report Form test object ox

Define Class demo as ReportListener
	lInSummary = .F.
	nSummaryHeight = 600 && 960th inch
	nSummaryStart = NULL

Procedure BeforeBand( nBandObjCode, nFRXRecNo	)
	This.lInSummary = nBandObjCode = 8
	This.nSummaryStart = NULL
EndProc

Procedure AfterBand( nBandObjCode, nFRXRecNo	)
	This.lInSummary = .F.
EndProc

Procedure render(nFRXRecNo,nLeft,nTop,nWidth,nHeight,;
	nObjectContinuationType, cContentsToBeRendered, GDIPlusImage)
	Local lnNewTop
	If This.lInSummary
		If IsNull(This.nSummaryStart)
			This.nSummaryStart = m.nTop
		EndIf
		lnNewTop = m.nTop - This.nSummaryStart + ;
			This.GetPageHeight() - This.nSummaryHeight
		DoDefault( nFRXRecNo, nLeft, m.lnNewTop, nWidth,nHeight,;
			nObjectContinuationType, cContentsToBeRendered, GDIPlusImage ;
		)
		NoDefault
	EndIf
EndProc                        

EndDefine