I have seen something similar. When modifying reports it sometimes sets the report to your default printer as a Specific printer unless you deliberately set to default. This seems to override SET PRINTER.
I use the following, downloaded from UT some time ago to clear all printer settings to default, just remember to reset any specific report printers after use

Local oFile, cEmptyStr, nReportCount
#Define cEmptyStr Space(0) &&Sets cEmptyStr value
nReportCount = 0
Clear
Modi Project ? Noshow Nowait &&Prompts the Project File name

*!* Loops into the Project Collection Object
For Each oFile In _vfp.ActiveProject.Files

If oFile.Type = 'R' &&Checks for Report File Type
Wait Window 'Clearing Fields in: ' +;
oFile.Name Timeout 1
Use (oFile.Name)
Go Top
Locate For ObjType = 1 And ObjCode = 53

If Found()
Replace Tag With cEmptyStr,; &&Clears the Tag, Tag2, Expr Fields
Tag2 With cEmptyStr
*,;
* Expr With cEmptyStr &&Remark this line to keep values in EXPR field
nReportCount = nReportCount + 1
Use
Endif

Endif

Endfor
*!* Displays Process Summary
Wait Window Alltrim(Str(nReportCount)) +;
' Report(s) Modified in Project ' +;
_Vfp.ActiveProject.Name