>>Can somebody help me with the proper syntax for the field commands in this sequence? (and the values for dbText and dbMemo)
>>Thanks
>>

>>oAccess = createobject("Access.application")
>>oAccess.visible= .t.
>>
>>newMDB = oAccess.NewCurrentDatabase("C:\accesstest")
>>tdfnew = oAccess.CurrentDb.CreateTableDef('testtable')
>>	
>>with tdfnew
>>.fields.append .CreateField("FirstName", "dbText")
>>.fields.append .CreateField("LastName", "dbText")
>>.fields.append .CreateField("Phone", "dbText")
>>.fields.append .CreateField("Notes", "dbMemo")
>>newMDB.TableDefs.append tdfnew
>>endwith
>>

>
>I happen to know 10 from documentation. Documentation is so weak that I don't know what would it be if boolean, date ...
>

oAccess = createobject("Access.application")
>oAccess.visible= .t.
>
>oAccess.NewCurrentDatabase("C:\accesstest.mdb")
>newMDB = oAccess.CurrentDb
>tdfnew = oAccess.CurrentDb.CreateTableDef('testtable')
>	
>with tdfnew
>.fields.append( .CreateField("FirstName", 10) )
>.fields.append( .CreateField("LastName", 10) )
>.fields.append( .CreateField("Phone", 10) )
>.fields.append( .CreateField("Notes", 10) )
>ENDWITH
>newMDB.TableDefs.append( tdfnew )

Cetin

Thanks Cetin
I've been playing around with it. Here is what I have so far in case anyone is interested.

#define dbLogical	1
#define dbNumber	2
#define dbInteger	3
#define dbLongInteger	4
#define dbCurrency	5
#define dbSingle	6
#define dbDouble	7
#define dbDateTime	8
#define dbBinary	9
#define dbText		10
#define dbOLEObject	11
#define dbMemo		12
#define dbReplication	15
#define dbDecimal	16

if file("C:\accesstest.mdb")
	delete file c:\accesstest.mdb
endif
public oAccess
oAccess = createobject("Access.application")
oAccess.visible= .t.

newMDB = oAccess.NewCurrentDatabase("C:\accesstest")
newtable = oAccess.CurrentDb.CreateTableDef('testtable')

with newtable
	.fields.append(.CreateField("Field1", dbLogical))
	.fields.append(.CreateField("Field2", dbNumber))
	.fields.append(.CreateField("Field3", dbInteger))
	.fields.append(.CreateField("Field4", dbLongInteger))
	.fields.append(.CreateField("Field5", dbCurrency))
	.fields.append(.CreateField("Field6", dbSingle))
	.fields.append(.CreateField("Field7", dbDouble))
	.fields.append(.CreateField("Field8", dbDatetime))
	.fields.append(.CreateField("Field9", dbBinary, 3))
	.fields.append(.CreateField("Field10", dbText, 3))
	.fields.append(.CreateField("Field11", dbOLEObject))
	.fields.append(.CreateField("Field12", dbMemo))
	.fields.append(.CreateField("Field15", dbReplication))
	.fields.append(.CreateField("Field16", dbDecimal))
endwith

oAccess.CurrentDb.TableDefs.append( newtable)

- Don