Returning arrays make sense in class methods only because array has to exist at the point where returned array is assigned to another array.

oDI = CREATEOBJECT("DbcInfo")

dbc2Convert = "C:\Program Files\Microsoft Visual FoxPro 9\Samples\Northwind\northwind.dbc"

aTables = oDI.GetDBCTableNames(dbc2Convert)
for i = 1 to alen(aTables)
	? aTables(i)
next
RETURN 

DEFINE CLASS DbcInfo AS Custom
	DIMENSION laTables[1]
	function GetDBCTableNames()
		lparameters myDBC
		select objectname as tablename ;
			from (myDBC) ;
			where objecttype = "Table" ;
			into array This.laTables
		return @This.laTables
ENDDEFINE

>Given the below:
>

>dbc2Convert = "\\tpdfiles\data\dfreeman\tip\data\rta\rta.dbc"
>aTables = GetDBCTableNames(dbc2Convert)
>for i = 1 to alen(aTables)
>? aTables(i)
>next
>
>**************************************************************************
>function GetDBCTableNames()
>lparameters myDBC
>select objectname as tablename ;
>from (myDBC) ;
>where objecttype = "Table" ;
>into array A1
>return A1
>

>Why do I get an error that says A1 is not an array? The select produces 6 records.
>
>Thanks