>Hi, I attempt to discover if a SQL Server is available in the network, so I run the code below, but it returns that there is no SQL Server there, but I have a SQl Server in the PC and I can connect to it.
>What im missing here?
>Thanks in Advance
>
>Peter
>
>

>LOCAL oSQLDMO AS SQLDMO.SQLserver
>LOCAL oNames AS SQLDMO.NameList
>oSQLDMO = CREATEOBJECT("SQLDMO.SQLserver")
>oNames = oSQLDMO.APPLICATION.ListAvailableSQLServers()
>FOR ix=1 TO oNames.COUNT
> ? oNames.ITEM[ix]
>ENDFOR
>

Peter,
It wouldn't work. Neither would some APIs (one is used by VFP data explorer). Those all assume SQL2000 and fail with 2005/2008 servers unless you explicitly change driver name.

These work for installed instances and registered servers. I haven't seen a reliable way to discover what is available on a network:

Local oSQLDMO2 as SQLDMO.SQLserver2,;
  oSQLDMO As SQLDMO.SQLserver,;
  oSG As SQLDMO.ServerGroup,;
  oSrv As SQLDMO.RegisteredServer

** get installed instances
oSQLDMO2 = Createobject("SQLDMO.SQLserver2")
oNames2 = oSQLDMO2.ListInstalledInstances()
For ix=1 To oNames2.Count
  ? oNames2.Item[ix]
Endfor
? '***************'

*** Get registered servers
oSQLDMO = Createobject("SQLDMO.SQLserver")
? 'SQL server groups count:', oSQLDMO.Application.ServerGroups.Count
For Each oSG In oSQLDMO.Application.ServerGroups
  ? Textmerge('SQL server group name:[<<oSG.Name>>] have <<oSG.RegisteredServers.Count>> registered servers')
  For Each oSrv In oSG.RegisteredServers
    ? oSrv.Name
  Endfor
Endfor

PS: MS documented that SQLDMO (and probably the APIs it uses) would be dropped in future SQL server versions. SQL SMO is the way to go but I don't know if there is a way to use it from VFP.