Hi Tracy,

>How do I run that on a machine that doesn't have .net or vfp developer but only the .net framework and the vfp runtimes?

It's a single EXE that you can run on any computer without installing it. The download is available on http://technet.microsoft.com/en-us/sysinternals/bb896645.aspx

ProcMon displays all file and registry activity. With the filter options you can limit the output to your application. I use the following program to leave traces in the log from inside a program:

*========================================================================================
* Create a log entry in the FILEMON protocol
*========================================================================================

	*--------------------------------------------------------------------------------------
	* find calling method, procedure or program
	*--------------------------------------------------------------------------------------
	Local laStack[1], lcMarker, lnLevel, lcProcedure
	lnLevel = AStackInfo(laStack)-1
	lcProcedure = Substr(Sys(16,m.lnLevel),At(" ",Sys(16,m.lnLevel),1)+1)
	lcMarker = Proper(Alltrim(Left(m.lcProcedure,At(" ",m.lcProcedure))))
	If not Empty(m.lcMarker)
		lcMarker = m.lcMarker + " in " 
	EndIf
	lcMarker = m.lcMarker + ;
			JustStem(Substr(Sys(16,m.lnLevel),At(" ",Sys(16,m.lnLevel),2)+1)) + ;
			", "+Transform(laStack[m.lnLevel,5])
	lcMarker = "#FILEMON# - " + Chrtran(lcMarker,"\/?","___")
				
	*--------------------------------------------------------------------------------------
	* Leave a marker
	*--------------------------------------------------------------------------------------
	=Directory(m.lcMarker)

Then you can search for #FILEMON# to link file and registry activity with the source code line.