*oform1.Show
i think this needs a 'read events' after the line oform1.Show
(nice form Mike)

k


>>Hi,
>>
>>Where can i find a outlook calendar activex to show calendar in vfp form, or a sample to use outlook calendar data.
>>
>>Best Regards
>
>

Public oform1
>oform1=createobject("form1")
>oform1.Show
>Return
>******************************************************
>Define Class form1 As Form
>
>    Height = 400
>    Width = 620
>    DoCreate = .T.
>    Caption = "Form1"
>    Name = "Form1"
>
>    Add Object cmdExit As CommandButton With ;
>        Top = 330, ;
>        Left = 504, ;
>        Height = 27, ;
>        Width = 84, ;
>        Caption = "E\<xit", ;
>        Name = "CmdExit"
>
>    Add Object cmdCalendar As CommandButton With ;
>        Top = 330, ;
>        Left = 12, ;
>        Height = 27, ;
>        Width = 84, ;
>        Caption = "\<Calendar", ;
>        Name = "CmdCalendar"
>
>    Add Object cmdInBox As CommandButton With ;
>        Top = 330, ;
>        Left = 108, ;
>        Height = 27, ;
>        Width = 84, ;
>        Caption = "\<In Box", ;
>        Name = "CmdInBox"
>
>    Add Object cmdSent As CommandButton With ;
>        Top = 330, ;
>        Left = 204, ;
>        Height = 27, ;
>        Width = 84, ;
>        Caption = "\<Sent Mail", ;
>        Name = "CmdSent"
>
>    Add Object cmdContact As CommandButton With ;
>        Top = 330, ;
>        Left = 300, ;
>        Height = 27, ;
>        Width = 84, ;
>        Caption = "\<AddressBook", ;
>        Name = "CmdContact"
>
>    Add Object cmdNewMail As CommandButton With ;
>        Top = 360, ;
>        Left =12 , ;
>        Height = 27, ;
>        Width = 84, ;
>        Caption = "New \<Mail", ;
>        Name = "cmdNewMail"
>
>    Add Object cmdNewTask As CommandButton With ;
>        Top = 360, ;
>        Left =108 , ;
>        Height = 27, ;
>        Width = 84, ;
>        Caption = "New \<Task", ;
>        Name = "cmdNewTask"
>
>    Add Object cmdNewContact As CommandButton With ;
>        Top = 360, ;
>        Left =204 , ;
>        Height = 27, ;
>        Width = 84, ;
>        Caption = "\<New Contact", ;
>        Name = "cmdNewContact"
>
>    Add Object cmdNewAppointment As CommandButton With ;
>        Top = 360, ;
>        Left =300 , ;
>        Height = 27, ;
>        Width = 110, ;
>        Caption = "New A\<ppointment", ;
>        Name = "cmdNewAppointment"
>
>    Add Object olecontrol1 As OleControl With ;
>        Top = 12, ;
>        Left = 12, ;
>        Height = 306, ;
>        Width = 588, ;
>        Name = "Olecontrol1", ;
>        OleClass = "OVCtl.OVCtl.1"
>
>    Procedure cmdExit.Click
>       Thisform.Release()
>    Endproc
>
>    Procedure cmdNewMail.Click
>       Thisform.olecontrol1.NewMessage()
>    ENDPROC
>
>    Procedure cmdNewTask.Click
>       Thisform.olecontrol1.NewTask()
>    Endproc
>
>    Procedure cmdNewContact.Click
>       Thisform.olecontrol1.NewContact()
>    ENDPROC
>
>    Procedure cmdNewAppointment.Click
>       Thisform.olecontrol1.NewAppointment()
>    Endproc
>
>    Procedure cmdCalendar.Click
>       Thisform.olecontrol1.Folder = "CALENDAR"
>       Thisform.Caption = "OutLook Calendar"
>       Thisform.Refresh()
>    Endproc
>
>    Procedure cmdInBox.Click
>       Thisform.olecontrol1.Folder = "INBOX"
>       Thisform.Caption = "OutLook InBox"
>       Thisform.Refresh()
>    Endproc
>
>    Procedure cmdSent.Click
>       Thisform.olecontrol1.Folder = "SENT ITEMS"
>       Thisform.Caption = "OutLook Sent Items"
>       Thisform.Refresh()
>    Endproc
>
>    Procedure cmdContact.Click
>       Thisform.olecontrol1.Folder = "CONTACTS"
>       Thisform.Caption = "OutLook Address Book"
>       Thisform.Refresh()
>    Endproc
>
>    Procedure olecontrol1.Init
>       This.Folder = "Calendar"
>    Endproc
>
>Enddefine