>Hello all,
>
>How can I copy a general memo, containing for example a WORD file, to a WORD file again ??
>
>Thanks
>Xavier
>
>X.D.Technology cc
>Software Development

create cursor wtest (wf g)
append blank
append general wf from ("c:\my documents\mytest.doc")
oform = createobject("form")
with oForm
  .addobject("olbW","Oleboundcontrol")
  .height = 420
  .width = 620
  with .olbW
	.top = 10
	.left = 10
	.height = 400
	.width = 600
	.controlsource = "wtest.wf"    		&& Embedded word doc
	.object.saveas("c:\temp\savedfromgen.doc")  && saved to disk
  endwith	
  .removeobject("olbW")
  .AddObject('cmdCommand1','cmdMyCmdBtn')  && Add Command button
  .AddObject("oleObject","oleWordObject")  && Add OLE object
  .cmdCommand1.Visible=.T.		&& Display the "Quit" Command button
  .oleObject.DoVerb(-1)			&& -1 for Edit
  .Show					&& Display the form
endwith	
READ EVENTS	&& Start event processing

DEFINE CLASS oleWordObject as OLEControl
	OleClass ="Word.document.8"			&& Server name
	OleTypeAllowed = 0 					&& Linked
	DocumentFile = "C:\temp\savedfromgen.doc"	&& This file would be created from embedded
ENDDEFINE

DEFINE CLASS cmdMyCmdBtn AS CommandButton  && Create Command button
	Caption = '\<Quit'  && Caption on the Command button
	Cancel = .T.  && Default Cancel Command button (Esc)
	Left = 1  && Command button column

	Top = 1  && Command button row
	Height = 25  && Command button height

	PROCEDURE Click
		CLEAR EVENTS  && Stop event processing, close form
ENDDEFINE

After first endwith, rest is to show you really saved the doc. Even just remout .show and read events so form wouldn't show at all.
Cetin