>I'm trying to use the drag and drop on a foxpro control other then the grid. For example, I'm trying to get the drag and drop to work on the image control. I have the drag and drop enabled for the control but when I try to drag a jpg file onto it during run time the cursor turns into a circle with a line though it. How can I get it to work?

Here is a quick sample:

Public loForm
loForm = Createobject('SampleForm')
loForm.Show()

Define Class SampleForm As Form
  Add Object myImage As Image With Top = 10, Left = 10, Height = 100, Width = 100, OLEDropMode=1

  Procedure myImage.OLEDragDrop
    Lparameters oDataObject, nEffect, nButton, nShift, nXCoord, nYCoord
    If oDataObject.GetFormat(15)	&& Files CF_DROP
      Local Array laFiles[1]
      oDataObject.GetData(15, @laFiles )
      This.Picture = laFiles[1]
    Endif
  Endproc

  Procedure myImage.OLEDragOver
    Lparameters oDataObject, nEffect, nButton, nShift, nXCoord, nYCoord, nState
    If m.nState == 0 And oDataObject.GetFormat(15) &&DRAG_ENTER and Files CF_HDROP
      This.OLEDropHasData = 1 &&DROPHASDATA_USEFUL
      This.OLEDropEffects = 4 &&DROPEFFECT_LINK
    Else
      This.OLEDropHasData = 0 &&DROPHASDATA_NOTUSEFUL
    Endif
  Endproc
Enddefine

Cetin