Thank you, Rick.

>Here's what I use that seems to work well:
>

>  RETURN "'" + TRANSFORM(TTOC(ltTime,1),"@R 9999-99-99 99:99:99") + "'"
>

>
>This comes from a stringification routine I use for strict dates that transform for Fox or SQL dates for use in SQL statements.
>
>

>************************************************************************
>FUNCTION TimeToCStrict
>****************************************
>***  Function: Returns time in strict time format or in SQL Server
>***            compliant format (llSql flag set).
>***      Pass: Datetime value
>***    Return: strict DateTime string, or SQL Server time string
>************************************************************************
>LPARAMETER ltTime, llSQL
>
>IF llSQL
>  IF EMPTY(ltTime)
>     RETURN "''"
>  ENDIF
>  
>  RETURN "'" + TRANSFORM(TTOC(ltTime,1),"@R 9999-99-99 99:99:99") + "'"
>ENDIF
>
>IF EMPTY(ltTime)
>   RETURN "{^}"
>ENDIF
>
>RETURN "{^" + TRANSFORM(TTOC(ltTime,1),"@R 9999-99-99 99:99:99") + "}"
>

>
>
>FWIW, I would avoid sending dates in string format to SQL Server whenever possible. Use named parameters and a variable instead:
>
>

>ptTimeStamp = Date() - 30
>lcSQL = "select * from someTable where TimeStamp > ?ptTimeStamp"
>SqlExec(lnHandle,lcSql)
>

>
>Prevents SQL injection and is easier to read and maintain.
>
>+++ Rick ---
>
>>Hi,
>>
>>I want to send to the SQL Server the following update command:
>>
>>

>>"update MyTable Set DateTimeColumn = " + TTOC(DateTime()) + " where Pk = " + nPk
>>

>>
>>The TTOC() does not seem to do the job as SQL Server returns an error. What would be the right syntax for sending the current Date and Time to update SQL Serrver column?
>>
>>TIA.