>Hello Everybody
>We have a WAN with 1400 users in 100 different locations.
>
>I need a cursor with all connected users (username,connectiondate,time,ipadress)
>
>Reading Active Directory informations ???
>Any other way ???
>
>Short example would be great.
>
>Best regards
>Albert

Would this work?

local loConnection, loSessions, loSession

lcServer                = "<Your Server>"
loConnection            = GetObject("WinNT://" + lcServer + "/LanmanServer")
loSessions                = loConnection.Sessions()

create cursor C_Sessions ;
    ( ;
        PK                I         autoinc    , ;
        Computer        C(64)            , ;
        ConnectedTime    I                , ;
        IdleTime        I                , ;
        Name            C(64)            , ;
        User            C(64)              ;
    )

For Each loSession in loSessions
    wait window 'Adding: ' + loSession.Name nowait
    with loSession
        try
            insert into C_Sessions ;
                    (    ;
                        Computer                , ;
                        ConnectedTime            , ;
                        IdleTime                , ;
                        Name                    , ;
                        User                      ;
                    ) ;
                values ;
                    ( ;
                        .Computer                , ;
                        .ConnectTime            , ;
                        .IdleTime                , ;
                        .Name                    , ;
                        .User                      ;
                    )
        catch
        endtry
    endwith
endfor

wait window 'Creating indexes...' nowait

index on    PK            tag PK
index on    Computer    tag Computer
index on    Name        tag Name
index on    User        tag User

wait clear