>>>>>>>Please see attach image
>>>>>>
>>>>>>what is wrong with MROW() and MCOL()?. Just pass thisform.Name as first parameter?
>>>>>
>>>>>Yes, when we change screen resolution then MROW() and MCOL() changes.
>>>>>
>>>>>Suppose I have following cods in 800x600
>>>>>
>>>>>

>>>>>DEFINE POPUP ABC SHORTCUT RELATIVE FROM 11,102 to 31,135  TITLE 'A R R I V A L'
>>>>>

>>>>>
>>>>>Then I change resolution to 1024x768 the popup will change its location
>>>>>
>>>>>So, I want to display POPUP from a fixed position in every resolution.
>>>>>
>>>>>I want POPUP every time appear from where SHAPE is located.
>>>>
>>>>How about:
>>>>

>>>>DEFINE POPUP shortcut SHORTCUT RELATIVE FROM thisform.Shape1.Top, thisform.Shape1.Left TITLE 'A R R I V A L'
>>>>

>>>>
>>>>NOT TESTED!
>>>
>>>
>>>

>>>DEFINE POPUP abc SHORTCUT RELATIVE FROM thisform.Shape1.Top, thisform.Shape1.Left TITLE 'A R R I V A L'
>>>

>>>
>>>sir, your above command does not work becuase SHAPE.LEFT does not match with MCOL()
>>>if shape1 left is 900 then there is no Mcol=900
>>>
>>>i have tested this function
>>>
>>>aa=mcols()
>>>it syas only 170
>>>
>>>so shape1's left is very bigger than screen.
>>>
>>>If I get proper mrow() and mcol() of shape1 then there will be no problem.
>>>All will be accurate.
>>
>>
>>When you click on button then MCOL() is on BUTTON not on SHAPE, I doubt that you want SHORTCUT to appear on button.
>
>I want popup to appear on shape1 by click button as
>
>popup left must be the left of shape1
>popup top must be the top of shape1
>popup width must be the width of shape1
>popup height must be the height of shape1

oTest = CREATEOBJECT("Form1")
oTest.Show(1)

**************************************************
*-- Form:         form1 (d:\all_zapl\test.scx)
*-- ParentClass:  form
*-- BaseClass:    form
*-- Time Stamp:   12/17/12 01:47:08 PM
*
DEFINE CLASS form1 AS form


    DoCreate = .T.
    Caption = "Form1"
    Name = "Form1"


    ADD OBJECT command1 AS commandbutton WITH ;
        Top = 154, ;
        Left = 49, ;
        Height = 27, ;
        Width = 84, ;
        Caption = "ClickMe", ;
        Name = "Command1"


    ADD OBJECT shape1 AS shape WITH ;
        Top = 14, ;
        Left = 175, ;
        Height = 108, ;
        Width = 153, ;
        Name = "Shape1"


     PROCEDURE Command1.Click
            DEFINE POPUP shortcut SHORTCUT RELATIVE  IN WINDOW (thisform.Name)
            DEFINE BAR _med_cut OF shortcut PROMPT "Cu\<t" ;
                KEY CTRL+X, "Ctrl+X" ;
                MESSAGE "Removes the selection and places it onto the Clipboard"
            DEFINE BAR _med_copy OF shortcut PROMPT "\<Copy" ;
                KEY CTRL+C, "Ctrl+C" ;
                MESSAGE "Copies the selection onto the Clipboard"
            DEFINE BAR _med_paste OF shortcut PROMPT "\<Paste" ;
                KEY CTRL+V, "Ctrl+V" ;
                MESSAGE "Pastes the contents of the Clipboard"
            DEFINE BAR 4 OF shortcut PROMPT "\-"
            DEFINE BAR _med_undo OF shortcut PROMPT "\<Undo" ;
                KEY CTRL+Z, "Ctrl+Z" ;
                MESSAGE "Undoes the last command or action"
            DEFINE BAR _med_redo OF shortcut PROMPT "Re\<do" ;
                KEY CTRL+R, "Ctrl+R" ;
                MESSAGE "Repeats the last command or action"
            DEFINE BAR 7 OF shortcut PROMPT "\-"
            DEFINE BAR _med_slcta OF shortcut PROMPT "Se\<lect All" ;
                KEY CTRL+A, "Ctrl+A" ;
                MESSAGE "Selects all text or items in the current window"

            ACTIVATE POPUP shortcut  AT _pix2fox(thisform.Shape1.Top,"V"), _pix2fox(thisform.Shape1.Left,"H") 
     ENDPROC 

ENDDEFINE
*
*-- EndDefine: form1
**************************************************


*** From http://support.microsoft.com/kb/106161
FUNCTION _pix2fox
      PARAMETER m.apixel,m.dimension
      RETURN m.apixel/FONTMETRIC(IIF(UPPER(m.dimension) = "H",6,1))