>Thanks for that!
>
>Does that install the VFP libraries too?

It installs anything you tell it to :)

Here's a sample script (I've cut out some code that allows the user to select where the installation goes, so if you get trouble let me know):

#define MyAppName "GFBL Claims Log"
#define MyAppVerName "GFBL Claims Log 1"
#define MyAppPublisher "Samaan Systems Ltd."
#define MyAppURL "http://SamaanSystems.com"
#define MyAppExeName "ClaimsLoader.exe"
#define MyAppVersion "1.0"

[Setup]
AppName={#MyAppName}
AppVerName={#MyAppVerName}
AppId=BPO2
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
DefaultDirName={pf}\GFBL Claims Log
AppVersion={#MyAppVersion}
DefaultGroupName=GFBL Claims Log
Compression=lzma
SolidCompression=true
OutputBaseFilename={#MyAppName} {#MyAppVersion} setup

[Messages]
BeveledLabel=© 2011 Samaan Systems Ltd.

[Tasks]
Name: desktopicon; Description: {cm:CreateDesktopIcon}; GroupDescription: {cm:AdditionalIcons}
Name: quicklaunchicon; Description: {cm:CreateQuickLaunchIcon}; GroupDescription: {cm:AdditionalIcons}; Flags: unchecked

[Files]
;**********************************************************************
;
;	Workstation component files
;
;**********************************************************************
Source: ClaimsLoader.exe; DestDir: {app}; Flags: replacesameversion

Source: C:\Program Files\Common Files\Microsoft Shared\VFP\gdiplus.dll; DestDir: {cf}\Microsoft Shared\VFP; Flags: sharedfile uninsneveruninstall restartreplace
Source: C:\Program Files\Common Files\Microsoft Shared\VFP\VFP9SP2\vfp9r.dll; DestDir: {cf}\Microsoft Shared\VFP; Flags: regserver sharedfile uninsneveruninstall restartreplace
Source: C:\Program Files\Common Files\Microsoft Shared\VFP\VFP9SP2\vfp9renu.dll; DestDir: {cf}\Microsoft Shared\VFP; Flags: sharedfile uninsneveruninstall restartreplace

Source: C:\Program Files\Common Files\Microsoft Shared\VFP\msvcr71.dll; DestDir: {sys}; Flags: uninsneveruninstall onlyifdoesntexist
Source: C:\Program Files\Common Files\Microsoft Shared\VFP\foxhhelp9.exe; DestDir: {cf}\Microsoft Shared\VFP; Flags: sharedfile uninsneveruninstall restartreplace
Source: C:\Program Files\Common Files\Microsoft Shared\VFP\foxhhelpps9.dll; DestDir: {cf}\Microsoft Shared\VFP; Flags: regserver sharedfile restartreplace uninsneveruninstall

[Icons]
Name: {group}\GFBL Claims Log; Filename: {app}\ClaimsLoader.exe; WorkingDir: {app}; IconFilename: {app}\ClaimsLoader.exe
Name: {commondesktop}\GFBL Claims Log; Filename: {app}\ClaimsLoader.exe; Tasks: desktopicon; WorkingDir: {app}; IconIndex: 0
Name: {commonappdata}\Microsoft\Internet Explorer\Quick Launch\GFBL Claims Log; Filename: {app}\ClaimsLoader.exe; Tasks: quicklaunchicon; WorkingDir: {app}; IconIndex: 0

[Run]
Filename: {cf}\Microsoft Shared\VFP\foxhhelp9.exe; Parameters: /regserver
Filename: {app}\ClaimsLoader.exe; Description: {cm:LaunchProgram,GFBL Claims Log}; Flags: nowait postinstall skipifsilent; OnlyBelowVersion: 0,6

[Registry]
; License for MSCOMCTL.OCX classes
Root: HKCR; Subkey: Licenses\ED4B87C4-9F76-11D1-8BF7-0000F8754DA1; ValueType: string; ValueData: knlggnmntgggrninthpgmnngrhqhnnjnslsh
; License for MSMAPI.OCX classes
Root: HKCR; Subkey: Licenses\899B3E80-6AC6-11cf-8ADB-00AA00C00905; ValueType: string; ValueData: wjsjjjlqmjpjrjjjvpqqkqmqukypoqjquoun

[Dirs]
Name: {app}; Permissions: everyone-modify